渐变纹理

与半兰伯特光照配合使用，因为半兰伯特最终会将点乘的结果控制在[0,1]之间，而正好用于渐变纹理的纹理坐标。虽然理论上讲会在[0,1]的范围内，但是因为是float类型，存在一定精度上的问题，即有可能是0.9999999999，也有可能是1.000000001，所以要注意渐变纹理的Wrap Mode，Clamp和Repeat可能会有不同的效果。
其实渐变纹理就是一个1D纹理，因为它纵坐标的颜色不变，改变横坐标才会改变颜色

Shader "Unlit/RampTexture"
{
    Properties
    {
        _Color("Color",Color)=(1.0,1.0,1.0,1.0)
        _RampTex("Ramp Tex",2D)="white" {}
        _Specualr("Specular",Color)=(1.0,1.0,1.0,1.0)
        _Gloss("Gloss",Range(30.0,100.0))=30.0
    }

    SubShader
    {
        Pass
        {
            Tags{"LighModel"="ForwardBase"}
            CGPROGRAM
            #include "Lighting.cginc"
            #include "UnityCG.cginc"

            #pragma vertex vert
            #pragma fragment frag

            fixed4 _Color;
            sampler2D _RampTex;
            float4 _RampTex_ST;
            fixed4 _Specualr;
            float _Gloss;

            struct a2v
            {
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float3 worldPos:TEXCOORD0;
                float3 worldNormal:TEXCOORD1;
                float2 uv:TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal).xyz;

                o.uv = TRANSFORM_TEX(v.texcoord, _RampTex);

                return o;
            }

            fixed4 frag(v2f i):SV_TARGET
            {
                float3 worldNormal = normalize(i.worldNormal);
                float3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                float3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
              //其实渐变纹理就是一个1D纹理，因为它纵坐标的颜色不变，改变横坐标才会改变颜色
                fixed halfLambert = 0.5*dot(worldNormal,worldLightDir)+0.5;
                fixed3 rampColor = tex2D(_RampTex,fixed2(halfLambert,halfLambert)).rgb * _Color.rgb;
                fixed3 diffuse = _LightColor0.rgb * rampColor;

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT;

                float3 halfNormal = normalize(worldLightDir+worldViewDir);
                fixed3 specular = _LightColor0.rgb * _Specualr * pow(saturate(dot(worldNormal,halfNormal)),_Gloss);

                return fixed4(ambient+diffuse+specular,1.0);
            }

            ENDCG
        }
    }

    Fallback "Specular"
}