向x86_64汇编说Hello[第二部分]

原文见part2
<a name="GxXu3"></a>

<a name="AwVRs"></a>

术语与概念

因为收到大量读者的述求，说第一篇文章不够清晰，所以本文以及后面将补充这部分内容。<br />寄存器 - 寄存器是处理器内部少量的存储。处理器的重点工作是处理数据。处理器可直接从内存获取数据，但是这样操作速度很慢。所以处理器有自己内部受限数量的数据存储即寄存器；<br />小端存储 - 小端存储是最低有效字节的地址最小；<br />大端存储 - 大端存储和小端存储相反；<br />系统调用 - 是用户级程序要求操作系统为其执行某些操作的方式。可以从系统表中看到。<br />栈 - 处理器仅有很少的受限数量的寄存器。堆栈是内存可寻址专用寄存器的连续区域如RSP, SS, RIP等。<br />段 - 每个汇编程序由段组成。有以下部分：

• data - 用于生成已初始化的变量或静态变量；
• bss - 用于生命未初始化过的变量；
• text - 用于代码

通常情况下，有16个通用寄存器- rax, rbx, rcx, rbp, rsp, rsi, rdi, r8, r9, r10, r11, r12, r13, r14, r15. 当然汇编编程相关的术语和概念的完整列表。若下文遇到不熟悉的术语时，我们将会解释相关概念。

<a name="bD7WU"></a>

数据类型

基础的数据类型有字节(bytes), 字(words)，双字(doublewords), 四字(quadwords)以及双四字。<br />1byte是8bits，1字是2bytes，双字是4bytes，。。。<br />目前本文只会涉及整型，整型分为两种：无符号整型和有符号整型。无符号双字整型范围为0 to 2^32 – 1，<br />有符号双字整型为–2^31 to +2^31 – 1...

<a name="ZxT7U"></a>

段

正如前文所述，每个汇编程序由段组成，它可以是数据段、文本段和BSS段的组合，首先我们关注数据段，有以下例子：

section .data
    num1:   equ 100
    num2:   equ 50
    msg:    db "Sum is correct", 10

这段代码的意思似乎很明确，但其中equ, db是什么意思呢？实际上NASM支持一些伪指令：

• DB, DW, DD, DQ, DT, DO, DY和DZ - 用于生成已初始化数据，例如：

;; Initialize 4 bytes 1h, 2h, 3h, 4h
db 0x01,0x02,0x03,0x04

;; Initialize word to 0x12 0x34
dw    0x1234

• RESB, RESW, RESD, RESQ, REST, RESO, RESY和RESZ - 用于声明未初始化变量；
• INCBIN - 导入外部二进制文件；
• EQU - 定义静态变量，例如：

;; now one is 1
one equ 1

• TIMES - 重复指令或数据。

<a name="Sz8BT"></a>

算术操作

• ADD - 整型加法
• SUB - 减法
• MUL - 无符号乘法
• IMUL - 有符号乘法
• DIV - 无符号除法
• IDIV - 有符号除法
• INC - 加1
• DEC - 减1
• NEG - 负

<a name="CjNQr"></a>

控制流

cmp指令用于执行两个值间的比较，该指令用于条件跳转：

;; compare rax with 50
cmp rax, 50

cmp指令仅是比较两个值，没有任何副作用，并且不会根据比较结果执行任何操作。对于比较后的任何操作，这里有一系列条件跳转指令：

• JE - 如果相等
• JZ - 如果为0
• JNE - 如果不相等
• JNZ - 如果非零
• JG - 如果第一个数大于第二个数
• JGE - 大于等于
• JA - 和JG类似，不过是针对无符号
• JAE - 和JGE，但是针对无符号类型

例如C中的if/else语句声明如下：

if (rax != 50) {
    exit();
} else {
    right();
}

那么在汇编中则是:

;; compare rax with 50
cmp rax, 50
;; perform .exit if rax is not equal 50
jne .exit
jmp .right

这里也有无条件跳转如：

JMP label

具体例子如：

_start:
    ;; ....
    ;; do something and jump to .exit label
    ;; ....
    jmp .exit

.exit:
    mov    rax, 60
    mov    rdi, 0
    syscall

<a name="ClEnw"></a>

示例

section .data
    ; Define constants
    num1:   equ 100
    num2:   equ 50
    ; initialize message
    msg:    db "Sum is correct\n"

section .text

    global _start

;; entry point
_start:
    ; set num1's value to rax
    mov rax, num1
    ; set num2's value to rbx
    mov rbx, num2
    ; get sum of rax and rbx, and store it's value in rax
    add rax, rbx
    ; compare rax and 150
    cmp rax, 150
    ; go to .exit label if rax and 150 are not equal
    jne .exit
    ; go to .rightSum label if rax and 150 are equal
    jmp .rightSum

; Print message that sum is correct
.rightSum:
    ;; write syscall
    mov     rax, 1
    ;; file descritor, standard output
    mov     rdi, 1
    ;; message address
    mov     rsi, msg
    ;; length of message
    mov     rdx, 15
    ;; call write syscall
    syscall
    ; exit from program
    jmp .exit

; exit procedure
.exit:
    ; exit syscall
    mov    rax, 60
    ; exit code
    mov    rdi, 0
    ; call exit syscall
    syscall