NodeMCU学习(四):与其他设备通信
TCP连接
TCP是计算机网络中运输层协议，是应用层协议http协议的支撑协议。两台远程主机之间可以通过TCP协议进行通信并交换信息，前提是，相互通信的两台主机之间知道彼此的IP地址和端口号。
打开网络调试助手，并将其设置为TCP Server
NodeMCU作为TCP客户端实现局域网内点亮Led灯（通过路由器中转）
NodeMCU可以被配置为一个TCP客户端，同时将一台网络设备（如电脑）配置为TCP服务器端，将NodeMCU连接到已经配置好的TCP服务器端上后，两者即可进行通信。
通信方法有两种，方法一是将NodeMCU设置为Soft AP模式，让电脑之间连接到它的WiFi上之后再与它进行通信。方法二是将NodeMCU和电脑同时连接到一个WiFi上，这样做的好处是与NodeMCU通信的设备数量不会受到较大的限制，因为将NodeMCU设置为
SoftAP模式时，最大可以连接到其上的设备数为8个。
首先使用方法二使两者连接到一起并进行通信，打开网络调试助手，将其协议类型设置为TCP Server(如图4-1)，更改本地端口号为任意值，在本次实验中被设置为1234。记住TCP Server的IP地址和端口号之后，将其打开(连接)。将程序中的IP地址和端口号换成上面设置好的值，并把NodeMCU的D0端口连接上一个Led，将程序烧录到Node MCU中。完成之后在网络调试助手中发送“0”或者“1”就会改变Led的状态。
NodeMCU程序如下：
/*-----------------------------------------------------------
written by helio, 2019
WiFiLed.ino - NodeMCU连接到路由器WiFi，将其配置为TCP客户端同时
与连接到路由器上的Tcp服务器设备（手机或电脑）建立Tcp连接
------------------------------------------------------------*/
const int Led = 16;
const char *RemoteIp = "192.168.1.105"; // 设置远程主机Ip地址
const int RemotePort = 1234; // 设置远程主机端口号
#include "ESP8266WiFi.h"
WiFiClient client; // 创建Tcp客户端
void setup()
{
Serial.begin(115200);
Serial.println();
WiFi.begin("CEET305", "office305"); // 设置连接到的WiFi名称和密码
Serial.print("Connecting...");
while (WiFi.status() != WL_CONNECTED)
{
delay(500);
Serial.print(".");
}
Serial.println();
Serial.println(WiFi.localIP()); // 打印NodeMCU的IP地址
if (!client.connect(RemoteIp, RemotePort)) // 建立tcp连接
{
Serial.println("Connected failed!");
return;
}
pinMode(Led, OUTPUT); // 设置GPIO16为输出模式
digitalWrite(Led, LOW); // 初始时，GPIO16输出低电平
}
void loop()
{
if (client.available())
{
char ch = client.read(); // 读取远程网络串口发来的数据
if (ch == '0')
digitalWrite(Led, LOW);
else if (ch == '1')
digitalWrite(Led, HIGH);
}
}
WiFiLed.ino函数解析
实例化一个 WiFiClient 对象，对象名称为client。WiFiClient类是在esp8266库中已经封装好的一个TCP客户端，使用它可以实现TCP客户端的实例化，与TCP服务器的连接、通信、状态判断等功能。随后，通过WiFiClient类的一个成员函数 connect() 设置需要连接的服务器的 IP地址和端口号，并与远程TCP服务器建立连接，通过其返回值判断是否连接成功。连接成功后，即可与服务器进行通信，通过类的成员函数 isavailable() 函数判断是否有消息从服务器端发送过来，并根据消息的内容对NodeMCU上GPIO16口的Led灯进行控制。
NodeMCU作为TCP服务器端实现局域网内点亮Led灯（不使用路由器）
第二种方法是将NodeMCU设置为softAP模式，相当于一种热点模式，设置好其WiFi的名字和密码之后，电脑（TCP客户端）即可通过WiFi连接到其上并与之进行通信。
首先把Led灯连接到NodeMCU的GPIO16口，之后将程序烧录至NodeMCU中之后，在串口监视器中可以看到设置成softAP模式成功（如图4-2），同时可以获知NodeMCU的IP地址。同时在电脑的WiFi管理中心中也可以看到刚刚设置的WiFi，将电脑连接到此WiFi。
程序烧录至NodeMCU中之后打开串口监视器
之后，在网络调试助手中（如图4-3），将协议类型设置为TCP Client，同时将IP地址设置为刚刚在串口监视器中得到的IP地址，端口设置为在程序中已经设置好的端口好。完成以上步骤之后，连接到TCP Server，连接上之后马上就会收到来自TCP Server发送来的消息“Hello from NodeMCU”，在TCP Client中发送”0”或者”1”即可控制Server端-NodeMCU上的Led灯。
设置网络调试助手
NodeMCU程序如下：
/*------------------------------------------------------------
written by helio, 2019
SoftApLed.ino - 将NodeMCU设置为soft-AP模式（热点模式）其他设备
可以连接到该热点,并将NodeMCU设置为Tcp服务器端，同时将其他设备（
手机，电脑）配置为Tcp客户端，并连接到NodeMCU服务器上，向其发送
控制消息
------------------------------------------------------------*/
#include <ESP8266WiFi.h>
const int Led = 16; // 将Led连接到GPIO16端口
const int LocalPort = 8266; // 设置ModeMCU端口
WiFiServer server(LocalPort);
void setup()
{
Serial.begin(115200);
Serial.println();
Serial.print("Setting soft_AP...");
if (WiFi.softAP("ESP8266", NULL))
Serial.print("Ready");
else
Serial.print("Failed");
Serial.println();
server.begin();
Serial.printf("TcpServerstarted,%s", WiFi.softAPIP().toString().c_str());
pinMode(Led, OUTPUT);
digitalWrite(Led, LOW);
}
void loop()
{
WiFiClient client = server.available(); // 等待客户端连接
if (client)
{
client.write("Hello from NodeMCU");
Serial.println("Client connected");
while (client.connected()) // 当客户端保持连接时，从客户端读取数据
{
if (client.available()) // 当客户端发送数据时
{
char ch = client.read();
if (ch == '0')
digitalWrite(Led, LOW);
else if (ch == '1')
digitalWrite(Led, HIGH);
}
}
}
client.stop(); // 断开连接
}
SoftApLed.ino 解析
实例化一个WiFi Serve类的对象server,并设置server的端口号，随后将Node MCU使用函数WiFi.softAP()设置为SoftAP模式，同时通过函数WiFi.softAPIP()获得其IP地址并打印到串口上，在loop循环中，通过WiFiServer类的一个成员函数available()等待客户端的连接，当有客户端连接至NodeMCU之后，通过client.write()函数往客户端发送“Hello from Node MCU”字符串并与客户端保持连接，再通过WiFiClient类的一个成员函数available接收从客户端发来的数据并通过其发送来的数据的不同从而控制NodeMCU上的Led灯。
阅读原文可访问我的个人博客
