DAX从入门到精通 5-2-1 Calculate案例
现在你已经学些了calculate的基础知识，或至少你已经知道它为何如此重要，章节的剩下部分我们提供了大量的案例。它们非常有益于我们学习。calculate函数本身很简单，它的复杂之处在于，使用它必须要求我们用上下文的思路在思考，同一个函数中，可能会有多种上下文情况，这个使得理解代码变得复杂。根据我们的经验，通过案例来学习calculate和筛选上下文，是非常好的方法。
单一列的过滤
calculate最简单的使用方法是只过滤一个列。举例，假设你要建立一个度量值，总是返回黑色产品的销售额，而不去考虑选择了什么颜色，函数可以这样写：
[SalesAmountBlack] :=
CALCULATE (
SUM ( Sales[SalesAmount] ),
Product[Color] = "Black"
)
如果你使用了这个函数，会得到如下的：
image.png
可以看到，新列总是显示黑色产品的销售额，即使每行的筛选条件是不同的颜色.
如果你把注意力集中在第三行 blue，它的值是这样计算的：函数读取了当前的筛选上下文，有就是蓝色。然后，calculate生成了一个新的条件--黑色，接着这个这个黑色的筛选条件替代了原始的筛选条件，然后计算表达式，最后把结果展示出来。其他行也是这样计算的。
显然，因为我们只是改写了color的筛选，其他列的还是保持原有的筛选条件。例如，如果你把calender year放到列中，你会看到所有的颜色相同年份都是一样的值，只有不同年份的时候，才有差别。
image.png
只过滤一个列，是很简单直接的。一个特点是如果你使用条件判断的方法，那么一次只能过滤一个列。例如，如果你要建立一个度量值，来计算那些unit price至少是 unit cost两倍的产品的销售额，可以试一下下面这个例子：
[HighProfitabilitySales] :=
CALCULATE (
SUM ( Sales[SalesAmount] ),
Product[Unit Price] >= Product[Unit Cost] * 2
)
可以看到，这次，条件判断引入了两个列：unit cost和unit price。即使DAX可以很容易的判断每个产品的这个条件，但是这样的写法是不对的。原因是，在判断写法的时候，calculate无法判断这个新的条件是要替代已有的unit price筛选器，还是unit cost筛选器，或者两者。所以，如果你按这样的写法，结果是一个报错的。
Calculation error in measure 'Sales'[HighProfitabilitySales]:
The expression contains
multiple columns, but only a single column can be used in a
True/False expression that is
used as a table filter expression.
对于这样的情况，没有任何使用布尔值的函数，如果你要在calculate中的条件判断引入多个列，那么你需要使用另外一种写法，也就是提供一些列的值，而不是用条件判断的方式。
上面案例的正确写法是这样：
[HighProfitabilitySales] :=
CALCULATE (
SUM ( Sales[SalesAmount] ),
FILTER ( Product, Product[Unit Price] >= Product[Unit Cost] *
2 )
)
这次不适用一个布尔表达式，而是在过滤参数中使用列表的方式。另外，我们不止过滤了一列，我们过滤了整个product表。在下图中，我们可以看到，HighProfitabilitySales可以正常工作。
image.png
这时候，calculate这样工作：filter的结果包含了多个列（这里是包含了product表的所有列），当这个新的条件添加到筛选上下文的时候，所有之前在product表存在的筛选条件都会被替换。换句话说，当在filter函数中第一个参数是表的时候，产生的结果就是替换该表所有的筛选条件。
有了之前的解释，我们会观察到有个地方没有完全的介绍清楚。我们说filter表达式替换了product表所有的筛选条件，因为filter返回的表包含了所有的product的列。但是，每行我们返回的值都是不一样的。
在行blue中，highprofitabilitysales返回的是蓝色产品的计算值，按我们所学的，不是应该忽略颜色返回所有产品函数条件计算的值么？因此，我们要花费一些时间，来认真的看下，上下文的计算顺序是怎么样的。下面这个代码是我们度量值使用的，每行都写了编号，便于我们定位函数的某部分
1. CALCULATE (
2. SUM ( Sales[SalesAmount] ),
3. FILTER (
4. Product,
5. Product[Unit Price] >= Product[Unit Cost] * 2
6. )
7. )
一开始是函数calculate，然后是计算表达式，这个都很简单，函数的筛选条件开始于第三行 filter。
filter是一个迭代函数，它在product表迭代，也就是第四行。此时的filter不会看到所有的行，它筛选的行是在当前上下文环境下看到的。问题来了，第四行中，是在哪个筛选上下文环境下？记得，calculate还没有创建新的上下文。它要后面才会产生。所以，它的上下文是在原始的筛选上下文产生的而不是calculate产生的。虽然有点绕口，但是这个简单的思考顺序，是很多DAX函数产生问题的点。
第四行的产品，是在原始的筛选上下文环境下生成了。对于blue的产品，product只有看到blue的产品，因此，filter只会迭代blue的产品，然后选择high profitability的产品。然后，calculate会移除color上的筛选条件，但是这个条件已经应用到之前的filter结果中了，也正如我们看到的。所以正确的理解filter的顺序非常重要，过滤是是被calculate产生的筛选条件替换的，而不是在calculate中的的filter函数替换。换句话说，calculate的filter参数的上下文环境是之前的原始上下文。而当calculate计算产生了新的上下文环境后，calculate根据新的环境计算表达式。
通过下面这个函数，可以有个完整的理解：
[HighProfitabilityALLSales] :=
CALCULATE (
SUM ( Sales[SalesAmount] ),
FILTER (
ALL ( Product ),
Product[Unit Price] >= Product[Unit Cost] * 2
))
这次，我们使用all（product）作为filter的表的参数。filter迭代的就不只是blue的产品，它总是迭代整个产品表，因为calculate会替换原始的筛选条件，所以我们会看到下面整个表：
image.png
HighProfitabilityALLSales 总是显示所有high profitability的产品，完全的忽略了在color上存在的过滤条件。我们可以总结下整个例子。
你可以在calculate中使用布尔表达式，但是，这时候，你只能引用单个列，如果引入了多列，那么系统会报错。
你可以使用filter或者其他的表函数作为calculate的参数。这时候，所有的列都是新的筛选上下文的组成部分。也就是calculate会替换这些列已经存在的筛选条件。
如果你是用了filter，那么filter使用原始的筛选上下文作为其筛选条件。如果你使用的是布尔表达式，那么calculate会替换该列现有的筛选上下文。
