优雅地用 Android Studio 打开 eclipse 项

注：本脚本近适用于单 project 项目，如果有其他 project 依赖，请自使用 eclipse 的导出 gradle 项目功能。

为什么会有此教程？

1. 直接用 as 导入 eclipse 项目，会破坏原有的目录结构;
2. 使用 eclipse 的导出 gradle 功能，再用 as 打开，恩，比较不错，但一般自动生成的 gradle 脚本需要再次手动优化，而且 gradle 版本老等问题。

我该怎么办？

在项目根目录新建 build.gradle 如下，而后用 Android studio 打开此文件即可 （注意，就是打开，不是导入），如果打开时有什么提示，点 ok 就行。

// 把此文件放在 eclipse 项目的跟目录，用 as 打开此文件即可。第一次可能会稍慢。
apply plugin: 'com.android.application'

android {
    // 可按需修改
    compileSdkVersion 21
    buildToolsVersion "25.0.3"

    // 可按需修改或删除
    defaultConfig {
        versionCode 1
        versionName '88888'
    }

    // 设置 sourceSets 为 eclipse 结构
    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src']
            renderscript.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
            jniLibs.srcDirs = ['libs']
        }
        androidTest.setRoot('tests')
        instrumentTest.setRoot('tests')
        debug.setRoot('build-types/debug')
        release.setRoot('build-types/release')
    }

    // 禁用 lint 检查
    lintOptions {
        checkReleaseBuilds false
        abortOnError false
    }

//  // 设置 Java 版本，可按需修改或删除
//    compileOptions {
//        sourceCompatibility JavaVersion.VERSION_1_6
//        targetCompatibility JavaVersion.VERSION_1_6
//    }

}

// :)
buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.3'
    }
}

// :P
repositories {
    jcenter()
}

// :P
dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
}