unity优化Unity干货程序猿大本营

Unity ShaderLab学习总结

2014-07-20  本文已影响53514人  DonaldW

Why Bothers？

为什么已经有ShaderForge这种可视化Shader编辑器、为什么Asset Store已经有那么多炫酷的Shader组件可下载，还是有必要学些Shader的编写？

2014-0718-1607-11-33.png

总之，Shader编写是重要的；但至于紧不紧急，视乎项目需求。

涉及范围

本文只讨论Unity ShaderLab相关的知识和使用方法。但，

使用Shader

2014-0720-1007-25-36.png

如上图，一句话总结：

  1. GameObject里有MeshRenderer，
  2. MeshRenderer里有Material列表，
  3. 每个Material里有且只有一个Shader；
  4. Material在编辑器暴露该Shader的可调属性。

所以关键是怎么编写Shader。

Shader基础

编辑器

使用MonoDevelop这反人类的IDE来编写Shader居然是让人满意的。有语法高亮，无语法提示。
如果习惯VisualStudio，可以如下实现.Shader文件的语法高亮。

Shader

Shader "ShaderLab Tutorials/TestShader"
{
    // ...
}
2014-0720-1707-17-42.png

Shader的名字会直接决定shader在material里出现的路径

SubShader

Shader "ShaderLab Tutorials/TestShader" {
    SubShader
    {
        //...
    }
}

一个Shader有多个SubShader。一个SubShader可理解为一个Shader的一个渲染方案。即SubShader是为了针对不同的渲染情况而编写的。每个Shader至少1个SubShader、理论可以无限多个，但往往两三个就足够。
一个时刻只会选取一个SubShader进行渲染，具体SubShader的选取规则包括：

按此规则第一个被选取的SubShader将会用于渲染，未被选取的SubShader在这次渲染将被忽略。

SubShader的Tag

Shader "ShaderLab Tutorials/TestShader" {
    SubShader
    {
        Tags { "Queue"="Geometry+10" "RenderType"="Opaque" }
        //...
    }
}

SubShader内部可以有标签（Tags）的定义。Tag指定了这个SubShader的渲染顺序（时机），以及其他的一些设置。

另，关于渲染队列和Batch的非官方经验总结是，一帧的渲染队列的生成，依次决定于每个渲染物体的：

这个渲染队列决定了之后（可能有dirty flag的机制？）渲染器再依次遍历这个渲染队列，“同一种”材质的渲染物体合到一个Batch里。

Pass

Shader "ShaderLab Tutorials/TestShader" {
    SubShader {
        Pass
        {
            //...
        }
    }
}

一个SubShader（渲染方案）是由一个个Pass块来执行的。每个Pass都会消耗对应的一个DrawCall。在满足渲染效果的情况下尽可能地减少Pass的数量。

Pass的Tag

Shader "ShaderLab Tutorials/TestShader" {
    SubShader {
        Pass
        {
            Tags{ "LightMode"="ForwardBase" }
            //...
        }
    }
}

和SubShader有自己专属的Tag类似，Pass也有Pass专属的Tag。
其中最重要Tag是 "LightMode"，指定Pass和Unity的哪一种渲染路径（“Rendering Path”）搭配使用。除最重要的ForwardBase、ForwardAdd外，这里需额外提醒的Tag取值可包括：

其他渲染路径相关的Tag详见下面章节“Unity渲染路径种类”。
具体所有Tag取值，可参考ShaderLab syntax: Pass Tags。

FallBack

Shader "ShaderLab Tutorials/TestShader"{
    SubShader { Pass {} }
    
    FallBack "Diffuse" // "Diffuse"即Unity预制的固有Shader
    // FallBack Off //将关闭FallBack
}

当本Shader的所有SubShader都不支持当前显卡，就会使用FallBack语句指定的另一个Shader。FallBack最好指定Unity自己预制的Shader实现，因其一般能够在当前所有显卡运行。

Properties

Shader "ShaderLab Tutorials/TestShader"
{
    Properties {
    _Range ("My Range", Range (0.02,0.15)) = 0.07 // sliders
    _Color ("My Color", Color) = (.34, .85, .92, 1) // color
    _2D ("My Texture 2D", 2D) = "" {} // textures
    _Rect("My Rectangle", Rect) = "name" { }
    _Cube ("My Cubemap", Cube) = "name" { }
    _Float ("My Float", Float) = 1
    _Vector ("My Vector", Vector) = (1,2,3,4)

    // Display as a toggle.
    [Toggle] _Invert ("Invert color?", Float) = 0
    // Blend mode values
    [Enum(UnityEngine.Rendering.BlendMode)] _Blend ("Blend mode", Float) = 1
    //setup corresponding shader keywords.
    [KeywordEnum(Off, On)] _UseSpecular ("Use Specular",  Float) = 0
    }
    
    // Shader
    SubShader{
        Pass{
          //...
          uniform float4 _Color;
          //...
          float4 frag() : COLOR{ return fixed4(_Color); }
          //...
             #pragma multi_compile __ _USESPECULAR_ON
          }
    }
    
    //fixed pipeline
    SubShader   {
        Pass{
            Color[_Color]
        }
    }
}

Shader中的数据类型

有3种基本数值类型：float、half和fixed。
这3种基本数值类型可以再组成vector和matrix，比如half3是由3个half组成、float4x4是由16个float组成。

数据类型影响性能

ShaderLab中的Matrix

当提到“Row-Major”、“Column-Major”，根据不同的场合，它们可能指不同的意思：

上述情况，互不相干。
然后，ShaderLab中，数学上是Column Vector、访问接口上是Row-Major、存储上是（尚未查明）。

ShaderLab中各个Space的坐标系

一般情况下，从Vertex Buff输入顶点到Vertex Shader，

v2f vert (appdata v)
{
    v2f o;
    o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
    // 1 、2、3是等价的，和4是不等价的
    // 因为是M在左、V在右，所以是Column Vector
    // 因为是HLSL/CG语言，所以是访问方式是Row-Major
    o.rootInView = mul(UNITY_MATRIX_MV, float4(0, 0, 0, 1)); // 1
    o.rootInView = float4(UNITY_MATRIX_MV[0].w, UNITY_MATRIX_MV[1].w, UNITY_MATRIX_MV[2].w, 1); // 2                
    o.rootInView = UNITY_MATRIX_MV._m03_m13_m23_m33;  // 3
    //o.rootInView = UNITY_MATRIX_MV[3]; // 4

    return o;
}

fixed4 frag (v2f i) : SV_Target
{
    // 因为是ViewSpace是右手坐标系，所以当root在view前面的时候，z是负数，所以需要-z才能正确显示颜色
    fixed4 col = fixed4(i.rootInView.x, i.rootInView.y, -i.rootInView.z, 1);
    return col;
}

struct appdata
{
    float4 vertex : POSITION;
};
struct v2f
{
    float4 rootInView : TEXCOORD0;
    float4 vertex : SV_POSITION;
};

Shader形态

Shader形态之1：固定管线

固定管线是为了兼容老式显卡。都是顶点光照。之后固定管线可能是被Unity抛弃的功能，所以最好不学它、当它不存在。特征是里面出现了形如下面Material块、没有CGPROGRAM和ENDCG块。

Shader "ShaderLab Tutorials/TestShader"
{
    Properties {
    _Color ("My Color", Color) = (.34, .85, .92, 1) // color
    }
    
    // Fixed Pipeline
    SubShader
    {
        Pass
        {
            Material{
            Diffuse [_Color]
            Ambient [_Color]
            }
            
            Lighting On
        }
    }
}

Shader形态之2：可编程Shader

Shader "ShaderLab Tutorials/TestShader"
{
    Properties {}
    
    SubShader
    {
        Pass
        {
          // ... the usual pass state setup ...
          
          CGPROGRAM
          // compilation directives for this snippet, e.g.:
          #pragma vertex vert
          #pragma fragment frag
          
          // the Cg/HLSL code itself
          float4 vert(float4 v:POSITION) : SV_POSITION{
            return mul(UNITY_MATRIX_MVP, v);
          }
          float4 frag() : COLOR{
            return fixed4(1.0, 0.0, 0.0, 1.0);
          }
          ENDCG
          // ... the rest of pass setup ...
          }
    }
}
编译指令 示例/含义
#pragma vertex name
#pragma fragment name 		替换name，来指定Vertex Shader函数、Fragment Shader函数。
#pragma target name 替换name（为2.0、3.0等）。设置编译目标shader model的版本。
#pragma only_renderers name name ...
#pragma exclude_renderers name name... 		#pragma only_renderers gles gles3，
#pragma exclude_renderers d3d9 d3d11 opengl，
只为指定渲染平台（render platform）编译
数据结构 含义
appdata_base vertex shader input with position, normal, one texture coordinate.
appdata_tan vertex shader input with position, normal, tangent, one texture coordinate.
appdata_full vertex shader input with position, normal, tangent, vertex color and two texture coordinates.
appdata_img vertex shader input with position and one texture coordinate.

Shader形态之3：SurfaceShader

Shader "ShaderLab Tutorials/TestShader"
{
    Properties {   }

    // Surface Shader
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float4 color : COLOR;
      };
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = 1;
      }
      ENDCG
    }
    FallBack "Diffuse"
}

struct SurfaceOutput {
    half3 Albedo; // 纹理颜色值（r, g, b)
    half3 Normal; // 法向量(x, y, z)
    half3 Emission; // 自发光颜色值(r, g, b)
    half Specular; // 镜面反射度
    half Gloss; // 光泽度
    half Alpha; // 不透明度
};

Shader形态之4：Compiled Shader

点击a.shader文件的“Compile and show code”，可以看到该文件的“编译”过后的ShaderLab shader文件，文件名形如Compiled-a.shader。
其依然是ShaderLab文件，其包含最终提交给GPU的shader代码字符串。
先就其结构进行简述如下，会发现和上述的编译前ShaderLab结构很相似。


// Compiled shader for iPhone, iPod Touch and iPad, uncompressed size: 36.5KB
// Skipping shader variants that would not be included into build of current scene.
Shader "ShaderLab Tutorials/TestShader"
{
    Properties {...}
    SubShader {
        // Stats for Vertex shader:
        //        gles : 14 avg math (11..19), 1 avg texture (1..2)
        //       metal : 14 avg math (11..17)
        // Stats for Fragment shader:
        //       metal : 14 avg math (11..19), 1 avg texture (1..2)
        Pass {
            Program "vp" // vertex program
            {
                SubProgram "gles" {
                    // Stats: 11 math, 1 textures
                    Keywords{...} // keywords for shader variants ("uber shader")

                    //shader codes in string
                    "
                    #ifdef VERTEX
                    vertex shader codes
                    #endif

                    // Note, on gles, fragment shader stays here inside Program "vp"
                    #ifdef FRAGMENT
                    fragment shader codes
                    #endif
                    " 
                }

                SubProgram "metal"  {
                    some setup
                    Keywords{...}

                    //vertex shader codes in string
                    "..."
                }
            }

            Program "fp" // fragment program
            {
                SubProgram "gles" {
                    Keywords{...}
                    "// shader disassembly not supported on gles" //(because gles fragment shader codes are in Program "vp") 
                }

                SubProgram "metal" {
                    common setup
                    Keywords{...}

                    //fragment shader codes in string
                    "..."
                }
            }
        }
    }

    ...
}

Unity渲染路径（Rendering Path）种类

概述

开发者可以在Unity工程的PlayerSettings设置对渲染路径进行3选1：

渲染路径的内部阶段和Pass的LightMode标签

每个渲染路径的内部会再分为几个阶段。
然后，Shader里的每个Pass，都可以指定为不同的LightMode。而LightMode实际就是说：“我希望这个Pass在这个XXX渲染路径的这个YYY子阶段被执行”。

Deferred Ligting

|渲染路径内部子阶段|对应的LightMode|描述
|-|-|
|Base Pass|"PrepassBase"|渲染物体信息。即把法向量、高光度到一张ARGB32的物体信息纹理上，把深度信息保存在Z-Buff上。|
|Lighting Pass|无对应可编程Pass|根据Base Pass得出的物体信息，在屏幕坐标系下，使用BlinnPhong光照模式，把光照信息渲染到ARGB32的光照信息纹理上（RGB表示diffuse颜色值、A表示高光度）
|Final Pass|"PrepassFinal"|根据光照信息纹理，物体再渲染一次，将光照信息、纹理信息和自发光信息最终混合。LightMap也在这个Pass进行。

Forward Rendering

|渲染路径内部子阶段|对应的LightMode|描述
|-|-|
|Base Pass|"ForwardBase"|渲染：最亮一个的方向光光源（像素级）和对应的阴影、所有顶点级光源、LightMap、所有LightProbe的SH光源（Sphere Harmonic，球谐函数，效率超高的低频光）、环境光、自发光。|
|Additional Passes|"ForwardAdd"|其他需要像素级渲染的的光源
注意到的是，在Forward Rendering中，光源可能是像素级光源、顶点级光源或SH光源。其判断标准是：

另外，配置成“Auto”的光源有更复杂的判断标注，截图如下：

2014-0720-1607-31-40.png
具体可参考Forward Rendering Path Details。

Vertex Lit

|渲染路径内部子阶段|对应的LightMode|描述
|-|-|
|Vertex|"Vertex"|渲染无LightMap物体|
|VertexLMRGBM|"VertexLMRGBM"|渲染有RGBM编码的LightMap物体
|VertexLM|"VertexLM"|渲染有双LDR编码的LightMap物体

不同LightMode的Pass的被选择

一个工程的渲染路径是唯一的，但一个工程里的Shader是允许配有不同LightMode的Pass的。
在Unity，策略是“从工程配置的渲染路径模式开始，按Deferred、Forward、VertxLit的顺序，搜索最匹配的LightMode的一个Pass”。
比如，在配置成Deferred路径时，优先选有Deferred相关LightMode的Pass；找不到才会选Forward相关的Pass；还找不到，才会选VertexLit相关的Pass。
再比如，在配置成Forward路径时，优先选Forward相关的Pass；找不到才会选VertexLit相关的Pass。

移动设备GPU架构简述

《The Mali GPU: An Abstract Machine》系列以Arm Mali GPU为例子给出了全面的讨论，现简述如下：

参考资源

上一篇 下一篇

猜你喜欢

热点阅读