30、[VBA入门到放弃笔记] 数组的赋值

• 定义数组的时候，数组开始是没有数据的，我们需要将数据放进数组，然后进行操作。
• 操作数组，一般遵从这样的流程。
  • 数组赋值，将数据放进数组。
  • 操作数组，处理数据，获得想要的结果。
  • 将结果输出到工作表。
• 这样看起来比直接操作工作表麻烦，但实际上比直接操作工作表要快很多很多。

---

• 数组的赋值
• 1、循环赋值，下面代码生成一个1-10序列的一维数组。

Sub ss()
   Dim arr(1 To 10) As Long
   Dim i As Long
   For i = 1 To 10
       arr(i) = i
       Debug.Print arr(i)
   Next
End Sub

结果

• 2、直接从工作表中获取

数据源

Sub bb()
Dim arr()
arr = Sheets("数组").Range("a1").CurrentRegion.Value
End Sub

结果

• 当然，我们也可以通过循环将单元格的值写入数组，但这种方式效率太差，直接读取单元格区域效率更佳。
• Dim arr()这里声明的是一个没有指定大小的数组，它可以是任意大小的，视乎工作表里数据的多少（Range的CurrentRegion属性）而变化，换言之，这是一个动态数组，随动态单元格变化而变化。
• 数组直接读取单元格区域的，返回的都是二维数组。

Sub vv()
Dim arr(), brr()
arr = Range("a1:a6").Value
brr = Range("a1:b1").Value
End Sub

Paste_Image.png

---

• 区别 dim arr 和 dim arr()
• 1、数组不能只是一个元素，如下面报错。

1 2

• 注意，图1 dim arr()声明的是一个数组；图2 dim arr 声明的是一个Variant变量，它不是数组，因此不会报错。

3

• 图3，arr是Variant变量并不是数组，但通过赋值后，就变成数组了。如果将dim arr，改为 Dim arr()，定义arr为数组，则上面代码出错，见图4

4

• 在CurrentRegion添上 .value后就可以了,见图5

5

• 还有一些奇怪的现象，可以看下图，F8运行代码，数组crr那里报错。

Sub vv()
Dim arr(), brr(), crr()
arr = Range("a1:b6")
brr = Sheets("数组").Range("a1:b6").Value
crr = Sheets("数组").Range("a1:b6")
End Sub

Paste_Image.png

---

如果不想麻烦，就这样定义（数组） Dim arr

练习：将上面例子中工资大于等于300的提取出来。

练习

• 操作单元格可以这么写代码。

Sub vv()
    Dim i As Long, rng As Range
    For i = 2 To 6
        If Cells(i, 2) >= 300 Then
            If rng Is Nothing Then
                Set rng = Cells(i, 1).Resize(1, 2)
            Else
                Set rng = Union(Cells(i, 1).Resize(1, 2), rng)
            End If
        End If
    Next
    rng.Copy Range("d2")
End Sub

• 数组可以这么写

       Sub vv()
1:        Dim arr, i As Long, k As Long
2:        arr = Range("a2:b6").Value
3:        For i = 1 To UBound(arr)
4:            If arr(i, 2) >= 300 Then
5:                k = k + 1
6:                arr(k, 1) = arr(i, 1)
7:                arr(k, 2) = arr(i, 2)
8:            End If
9:        Next
10:        Range("d2").Resize(k, 2) = arr
       End Sub

• 第2行代码，将数据赋值到数组arr
• 第3行代码，For循环遍历数据
• 第4行代码，操作数组就如操作单元格区域一样，arr(i, 2),就是工资的数据。
• 第5行代码，对符合条件的数据进行计数
• 第6、7行代码，将符合条件的数据，替换到数组arr自身当中。如k=1时，提取的是郭靖的数据，那么此时数组arr的第一行数据就不是令狐冲的数据了，郭靖代替了令狐冲，k=2时，继续类似替换......由于数组的改变是发生在内存当中的，因此不需要担心会对工作表中的数据造成影响。如下图，arr(1,1)和arr(3,1)是2个郭靖的数据。

Paste_Image.png

• 第10行代码，是输出数组中符合条件的数据到工作表中。注意K的值，K是符合条件的数据条数，这个例子中K=3，用resize属性，可以截取数组大小，数组arr实际上是5行2列大小，但这里用resize，截取K（3）行2列的部分，也就是符合条件的数据。

• 运行代码至第10行，可以看到数组arr前面3条数据都是更改了的，是工资大于等于300的符合条件数据，因此 K 的值就是用来截取这部分的数据，输出到工作表上。

  
  Paste_Image.png
• 当然，我们也可以另外新建一个数组，用来存储数组arr中符合条件的数据。
• 数组是一个隐形的空间，一个隐形的‘工作表’，是一个随意任我们拿捏的mz。