Unity custom shader中调用内置Lightmap
刚开始接触unity shader的时候发现自己写的unlit shader不支持烘焙场景中的光，无论烘焙场景什么样，自己写的shader根本不接受烘焙的影响，而unity自带的standard shader及其他一系列都完美支持，那自己写的shader要如何像unity自带shader那样支持烘焙呢？
其实很简单，几行代码就能搞定。让我们先来看一个场景
场景
这是我在unity中搭建了一个临时场景并烘焙好（具体过程可看这个视频），然后这个猴脸用了standard shader，现在我把他换成我自己写的一个最简单的diffuse shader，只输出贴图颜色，然后就成了这样
失败的场景
贴图丑了点，大家无视好了。。。
现在发现，咦，为什么不像刚刚那样在猴脸的左侧有橙黄色的光叠加而右侧有蓝光的叠加呢？这是因为那几行神奇的代码没有加，我们现在来看要加什么。
Shader "Unlit/Monkey"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {}
_Color ("Main Color",Color) = (1,1,1,1)
}
SubShader
{
Tags { "RenderType"="Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile LIGHTMAP_OFF LIGHTMAP_ON
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
float2 uv1 : TEXCOORD1;
};
struct v2f
{
float2 uv : TEXCOORD0;
float4 vertex : SV_POSITION;
#ifdef LIGHTMAP_ON
float2 uvLM : TEXCOORD1;
#endif
};
sampler2D _MainTex;
float4 _MainTex_ST;
fixed4 _Color;
v2f vert (appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.uv, _MainTex);
#ifdef LIGHTMAP_ON
o.uvLM = v.uv1.xy * unity_LightmapST.xy + unity_LightmapST.zw;
#endif
return o;
}
fixed4 frag (v2f i) : SV_Target
{
// sample the texture
fixed4 col = tex2D(_MainTex, i.uv);
col *= _Color;
#ifdef LIGHTMAP_ON
fixed3 lm = DecodeLightmap(UNITY_SAMPLE_TEX2D(unity_Lightmap,i.uvLM));
col.rgb *= lm;
#endif
return col;
}
ENDCG
}
}
}
首先第一条要在CGPROGRAM后添加一行
#pragma multi_compile LIGHTMAP_OFF LIGHTMAP_ON
这样shader就可以判断lightmap开没开了。
然后在vertex shader里添加
#ifdef LIGHTMAP_ON
o.uvLM = v.uv1.xy * unity_LightmapST.xy + unity_LightmapST.zw;
#endif
把lightmap的uv准备好之后使用。
这里这样写是和unity的源码TRANSFORM_TEX一致
// Transforms 2D UV by scale/bias property
#define TRANSFORM_TEX(tex,name) (tex.xy * name##_ST.xy + name##_ST.zw)
不过不能直接调用TRANSFORM_TEX是因为unity_LightmapST这个东西在ST之前没有下划线_，所以没法用现成的方法了。
再来到fragment shader里就和获取主贴图一样操作了
#ifdef LIGHTMAP_ON
fixed3 lm = DecodeLightmap(UNITY_SAMPLE_TEX2D(unity_Lightmap,i.uvLM));
col.rgb *= lm;
#endif
这里为什么要用DecodeLightmap又要用UNITY_SAMPLE_TEX2D来解读ligtmap呢？实际上unity生成的lightmap的有两种编码格式：doubleLDR和RGBM，根据冯乐乐前辈的考证
Unity使用了两种编码方式来存储lightmap:
1、doubleLDR，需要一张rgb24贴图
2、RGBM，需要一张rgba32贴图
在移动设备上使用doubleLDR格式，可以获得更快的计算速度。它只用到了lightmap的RGB通道。
PC上则使用RGBM格式，可以获得更广的亮度范围，而牺牲一点速度。它使用了贴图的RGBA通道，而A通道是用来做乘法，所以称为RGBM格式。
这两种格式的差异就是导致不同平台下lightmap表现不同的原因，当然Unity会在切换平台时帮我们对贴图进行转换，而不需要太关心这个差异。
我们这样解读lightmap才能得到正确的颜色值而且不必担心因为平台不同造成的差异。
其实烘焙分为两种模式，有向的和无向的，如下图
上面的解析光照贴图方式是针对无向模式，有向模式应该这样解析
float4 lightmapDir = UNITY_SAMPLE_TEX2D_SAMPLER(unity_LightmapInd, unity_Lightmap, i.uvLM);
float3 lm = DecodeDirectionalLightmap(col,lightmapDir,normal);
unity_LightmapInd代表有向模式下烘焙出来的包含光照方向的光照贴图（是的！有向模式会烘焙出两张光照贴图，一张里储存颜色，一张里储存方向），然后有个方法叫DecodeDirectionalLightmap，需要传入颜色（比如说物体贴图的颜色，或者自定义的颜色，看最终想要的效果来决定），解析出来的光照贴图颜色以及世界坐标下的法线，这样出来的最终结果就是有向烘焙模式下光照贴图的信息了。
最终，我们自己写的shader也能支持烘焙了。
成功的场景
说完如何支持lightmap，我们再来看看如何支持light probes。我们在烘焙场景的时候，有时候场景中的某些东西不是static，也就是不是固定不动的，这样烘焙好的结果无法应用到这种在场景中动来动去的物件，而我们希望这样的物件依然受到烘焙的影响，那么这个时候就需要light probes了。
由于弄light probes挺麻烦的，所以我直接使用了这篇博客中的场景，然后加上了几行代码来支持light probes。我们先来看结果（这次我会做动图了！）
这个方块在动到黄色区域的时候呈现偏黄的颜色，而到了蓝色区域就会偏蓝。这其实就是在利用unity shader中自带的一个方法
ShadeSH9来实现的，具体代码如下
Shader "Unlit/LightProbes"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {}
_Color ("Main Color",Color) = (1,1,1,1)
}
SubShader
{
Tags { "RenderType"="Opaque" "LightMode" = "ForwardBase" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
float3 normal : NORMAL;
};
struct v2f
{
float2 uv : TEXCOORD0;
float4 vertex : SV_POSITION;
fixed3 SHLighting : COLOR;
};
sampler2D _MainTex;
float4 _MainTex_ST;
fixed4 _Color;
v2f vert (appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.uv, _MainTex);
float3 worldNormal = UnityObjectToWorldNormal(v.normal);
o.SHLighting = ShadeSH9(float4(worldNormal,1));
return o;
}
fixed4 frag (v2f i) : SV_Target
{
// sample the texture
fixed4 col = tex2D(_MainTex, i.uv);
col *= _Color;
col.rgb *= i.SHLighting;
return col;
}
ENDCG
}
}
}
这里有一点要记住，自定义的shader一定要写上Tags{"LightMode" = "ForwardBase"}，即是说要指定好LightMode，不指定的话ShadeSH9会返回黑色（全黑的那种），你完全不会想看到的颜色。
