SAS编程：Figure中，X轴坐标显示文字过长如何处理？

在日常的出图过程中，可能会遇到坐标显示文字过长、拥挤、跨行的现象，这个问题如何解决呢？

常规的方法有两种。第一种，精简显示内容，例如，去掉不必要的文字、用缩写代替长文字；第二种，缩小文字显示大小。应用第一种方法的情况较多，因为一般公司对TFL输出的字体大小都有要求，不允许改动字体大小。当使用缩写代替长文字时，在Footnote中，一般会对缩写内容进行解释说明。

下面介绍另一种理X轴坐标显示文字过长问题的方法——GTL中的AxisLegend语句。先看一下SAS文档中的官方介绍：

Generates consecutive integers for display as axis-tick values in the graph, and creates a legend that correlates those integers with the actual tick values that they represent.
（生成连续整数，作为图中坐标轴的显示值；并创建一个图标，将这些整数与它们所表示的实际值相关联）

选用SASHELP逻辑库中的Cars数据集进行编程说明，输出某制造商各型号汽车的里程数柱状图，选用的数据内容如下。我们可以看到，汽车类型比较多，有13种，可以预见柱状图的X轴会比较拥挤。

***Get analysis data;
data dodge;
  set sashelp.cars;
  where make = "Dodge";
  keep make  model  MPG_Highway;

  proc sort;
    by descending mpg_highway;
run;

Dataset

先展示常规出图的代码，这个并没有对过长的显示进行处理。

***Create the template for figure output;
proc template;
  define statgraph discretelegend ;
    begingraph;
      entrytitle "Mileage for Vehicles Made by Dodge";

      layout overlay;
        barchart category=model response=mpg_highway / stat=mean ;
      endlayout;
    endgraph;
  end;
run;

***Render the template；
proc sgrender data=dodge template=discretelegend ;
run;

输出的结果如下，可以看到分类变量Model的内容直接输出在X轴上，显得很拥挤。有时候这种显示，也是可以接受的，但如果在这种情况下还发生换行，一般是不被接受。

Output 1

---

如果这种显示不被接受的话，我们可以应用axislegend语句进行调整。该语句会使坐标轴上显示有序整数，在图标部分显示整数以及对应的分类内容。可以参考如下代码：

***Create the template for figure output;
proc template;
  define statgraph axislegend ;
    begingraph;
      entrytitle "Mileage for Vehicles Made by Dodge";

      layout overlay / xaxisopts=(name="xaxis" discreteopts=(tickvaluefitpolicy=extract)) ;
        barchart category=model response=mpg_highway / stat=mean ;
        axislegend "xaxis";
     endlayout;
    endgraph;
  end;
run;

***Render the template;
proc sgrender data=dodge template=axislegend;
run;

输出结果如下，X轴坐标轴的显示有序数字，数字与对应的内容以图标的形式在图的底部显示，从而避免坐标轴显示内容过于拥挤的情况发生。

Output 2

使用axislegend语句有一些注意点：

1. 坐标轴的设置属性时必须需要使用Name=选项，用于axislegend语句的引用；
2. 坐标轴必须是离散的坐标轴(TYPE=DISCRETE)；
3. 坐标轴必须使用TICKVALUEFITPOLICY=EXTRACT 或者TICKVALUEFITPOLICY=EXTRACTALWAYS选项。

以上就是X轴坐标显示文字过长的处理方法，若有疑问，欢迎评论区留言反馈！

参考资料：SAS® 9.4 Graph Template Language: Reference, Fifth Edition.