快速切换IP地址，快到起飞

公司整治上网环境，给工作电脑指配了固定IP，在单位上网只能用它。带电脑回家加班，就需要设置成自动获取IP和DNS，第二天到单位又设置回固定IP地址……日复一日，你懂得！手动操作很麻烦。

写了个批处理，能帮你在自动获取IP地址和固定IP地址之间来去自如、潇洒切换，快到起飞，你试一下！

1. 把下面代码框里的内容复制到一个新建的txt文件里，将文件重命名为IP切换助手.bat。

2. 注意：后缀.bat，别搞错了！！！，否则飞不起来。

3. 注意：文件编码格式是ANSI，别搞错了，否则会飞出乱码。

4. 然后，右键IP切换助手.bat文件，以管理员身份运行。试一下，爽不爽！

::-------------------------------- <说明>----------------------------------------------------
:: 批功能：实现预设固定IP地址和自动IP地址的快速切换。
:: 批版本：
::  v1.0 设置固定IP和自动获取IP；
::  v1.1 增加循环菜单及退出入口；
::  如有问题请联系我，谢谢！
::GPL
::----------------------------------------------------------------------------------------------
@echo off
title ----------IP切换助手(v1.1)----------

::--------------------------------<以下为需配置内容>-----------------------------------------
::这部分9个变量值（引号里的），都要修改成自己的
    @echo off
::设置网络连接名称，有的是“无线连接”，有的是“WLAN”根据自己实际设置
    set myWirelessName="WLAN"
    set myWireName="以太网"
::预设、固定的无线IP和网关
    set myWirelessIP="10.5.90.166"
    set myWirelessGateway="10.5.90.254"
::预设、固定的有线IP和网关
    set myWireIP="10.5.91.204"
    set myWireGateway="10.5.91.254"
::子网掩码和两个预设、固定的DNS地址
    set myMask="255.255.255.0"
    set myDNS1="10.0.231.11"
    set myDNS2="61.233.9.9"
::--------------------------------<以上为需配置内容>-----------------------------------------

:main
::切换选择
    echo.
    echo 请选择你要设置的IP类型(1 or 2 or 3)：
    echo     1.个人固定IP
    echo     2.自动获取IP
    echo     3.退出
    @echo off
    set /p choice=
    echo.
    if "%choice%"=="1" goto ip1
    if "%choice%"=="2" goto ip2
    if "%choice%"=="3" exit
    goto main

::设置固定的IP
:ip1
    echo Begin：设置个人固定IP开始...
    echo.
    echo step1：正在设置无线IP及子网掩码
    cmd /c netsh interface ip set address name=%myWirelessName% source=static addr=%myWirelessIP% mask=%myMask% gateway=%myWirelessGateway% gwmetric=1
    ::echo.
    echo step2：正在设置有线IP及子网掩码
    cmd /c netsh interface ip set address name=%myWireName% source=static addr=%myWireIP% mask=%myMask% gateway=%myWireGateway% gwmetric=1
    ::echo.

::设置固定的DNS服务器地址
    echo step3：正在设置DNS服务器
    cmd /c netsh interface ip add dnsservers name=%myWirelessName% address=%myDNS1% index=1
    ::echo.
    cmd /c netsh interface ip add dnsservers name=%myWirelessName% address=%myDNS2% index=2
    ::echo.
    cmd /c netsh interface ip add dnsservers name=%myWireName% address=%myDNS1% index=1
    ::echo.
    cmd /c netsh interface ip add dnsservers name=%myWireName% address=%myDNS2% index=2
    ::echo.
    echo End：恭喜！固定IP设置成功。
    goto main

::设置自动获取IP
:ip2
    echo Begin：IP自动设置开始...
    echo.
    echo step1：正在自动获取IP地址
    netsh interface ip set address name =%myWirelessName% source = dhcp
    echo step2：正在自动获取DNS服务器
    netsh interface ip set dns name =%myWirelessName% source = dhcp
    echo End：恭喜！自动IP设置成功。
    goto main