esp-8266 示例api或者小爱同学控制开关
2024-04-13 本文已影响0人
yichen_china
Arduino代码
/* * nodemcu引脚对应数字： * 16=D0; * 4=D2; * 0=D3; * 2=D4; * 14=D5; * 12=D6; * 13=D7; * 15=D8; * 3=D9; * 1=D10; * ESP-01引脚对应数字： * GPIO2 --2 舵机 -> 模拟量输出 * GPIO16--16 继电器 -> 开关量输出*/
#include <ESP8266WiFi.h>
#include <Servo.h>
#ifndef STASSID
#define STASSID "填写你的WiFi名称" //WiFi名称
#define STAPSK "填写你的WiFi密码" //WiFi密码
#endif
#define ANGLE_ON 76 //开灯时的舵机角度
#define ANGLE_OFF 153 //关灯时的舵机角度
#define ANGLE_NONE 110 //置空时的舵机角度
const char* ssid = STASSID;
const char* password = STAPSK;
int angle=ANGLE_NONE;//舵机角度
Servo myservo; //创造一个servo结构体
//创建服务器实例，指定要监听的端口为80端口
WiFiServer server(80);
void setup() {
Serial.begin(115200);
myservo.attach(4); //舵机信号线，接analogIn脚
myservo.write(angle);// 0~180°
//连接WiFi
Serial.println();
Serial.println();
Serial.print(F("WiFi start connect "));//用F函数将会把字符串放入RAM中，输出至串口
Serial.println(ssid);
WiFi.mode(WIFI_STA);//设置为接收WiFi模式
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(F("."));
}
Serial.println();
Serial.println(F("WiFi已连接！"));
//开启模块的服务器
server.begin();
Serial.println(F("模块服务端已开启！"));
//打印模块的IP地址
Serial.println(WiFi.localIP());
}
void loop() {
//监测客户端是否连接
WiFiClient client = server.available();
if (!client) {
return;//如果未连接就重新循环监测
}
// Serial.println(F("new client"));
client.setTimeout(1000); // default is 1000
//读取请求内容的第一行
String req = client.readStringUntil('\r');
Serial.println(F("请求: "));
Serial.println(req);
//匹配 请求-->信号变量
if (req.indexOf(F("/gpio/0")) != -1) {
angle = ANGLE_ON;//如果/gpio/0在请求内容中，发出开灯的信号
myservo.write(angle);// 0~180°
delay(1000);
myservo.write(ANGLE_NONE);//将舵机重新置空，以免一直受力损坏
}
else if (req.indexOf(F("/gpio/1")) != -1) {
angle = ANGLE_OFF;
myservo.write(angle);// 0~180°
delay(1000);
myservo.write(ANGLE_NONE);//将舵机重新置空，以免一直受力损坏
}
else {
Serial.println(F("无效请求"));
}
//读取或忽略余下的请求内容
while (client.available()) {
client.read();
}
//向客户端发送回答，HTML网页代码内容
//nagle算法会将它们分组为一个数据包
client.print(F("<!DOCTYPE html>\r\n<html xmlns='http://www.w3.org/1999/xhtml'>\r\n"));
client.print(F("<head>\r\n<meta charset='utf-8'/>\r\n<title>智能卧室灯</title>\r\n"));
client.print(F("<style type='text/css'>.state{text-align:center;font-size:80px;}"));
client.print(F(".on{text-align:center;font-size:200px;alink='#1a9e5f'}.off{text-align:center;font-size:200px;alink='#da4f43'}"));
client.print(F("</style><body><div class='state'>灯状态："));
client.print((angle>ANGLE_NONE) ? F("关</div>") : F("开</div>"));
client.print(F("<br><br><div class='on'><a href='http://"));//<br>换行
client.print(WiFi.localIP());
client.print(F("/gpio/0'>开</a></div><br><br><div class='off'><a href='http://"));
client.print(WiFi.localIP());
client.print(F("/gpio/1'>关</a></div></body></html>"));
// 客户端实际上将被“刷新”,然后断开连接
// 当函数返回并且“客户端”对象被销毁时
// 刷新=确保书面数据被服务端接收
Serial.println(F("客户端已挂起！"));
}
9164f30afe6c89de93742b73d9121b7f.png
使用浏览器打开
http://192.168.1.43
image.png
点击开关即可控制
开灯接口=http://192.168.1.43/gpio/0；
关灯接口=http://192.168.1.43/gpio/1。
（手机需要和NodeMCU在同一个路由器下，即连接的是同一个WiFi）
需要注意的是ESP8266可能连不上手机热点和5GWiFi，WiFi名字也最好不要带中文。
通过小爱同学控制
/*
* nodemcu引脚对应数字：
* 16=D0;
* 4=D2;
* 0=D3;
* 2=D4;
* 14=D5;
* 12=D6;
* 13=D7;
* 15=D8;
* 3=D9;
* 1=D10;
* ESP-01引脚对应数字：
* GPIO2 --2 舵机 ->模拟输出
* GPIO16--16 开关
*/
#define BLINKER_WIFI
#define BLINKER_MIOT_LIGHT
#include <Blinker.h>
#define SW_Pin 2 //输出开关脚
#define ON 1 //开关状态
#define OFF 0 //开关状态
char auth[] = "填写key";// blinker APP申请得到的key
char ssid[] = "填写WiFi名称";// WiFi名称
char pswd[] = "填写WiFi密码";// WiFi密码
// 新建组件对象
BlinkerButton Button1("btn-abc");
BlinkerNumber Number1("num-abc");
int counter = 0;
// Blinker APP中的按键执行函数
void button1_callback(const String & state)
{
BLINKER_LOG("get button state: ", state);
digitalWrite(SW_Pin, !digitalRead(SW_Pin));
}
// 小爱同学的指令执行函数,中介选择阿里云才能用https://diandeng.tech/doc/xiaoai
void miotPowerState(const String & state)
{
BLINKER_LOG("need set power state: ", state);
if (state == BLINKER_CMD_ON) {
digitalWrite(SW_Pin, OFF);
BlinkerMIOT.powerState("off");
BlinkerMIOT.print();
}
else if (state == BLINKER_CMD_OFF) {
digitalWrite(SW_Pin, ON);// 将开关引脚置为高电平
BlinkerMIOT.powerState("on");// 反馈电源状态为ON
BlinkerMIOT.print();// 将以上属性发送出去, 务必最后调用该函数
}
}
// 如果未绑定的组件被触发，则会执行其中内容
void dataRead(const String & data)
{
BLINKER_LOG("Blinker readString: ", data);
counter++;
Number1.print(counter);
}
void setup()
{
// 初始化串口
Serial.begin(115200);
BLINKER_DEBUG.stream(Serial);
// 初始化LED的IO
pinMode(SW_Pin,OUTPUT);
digitalWrite(SW_Pin, ON);//先开启
// 初始化blinker
Blinker.begin(auth, ssid, pswd);
Blinker.attachData(dataRead);
Button1.attach(button1_callback);
BlinkerMIOT.attachPowerState(miotPowerState);
}
void loop() {
Blinker.run();
}
参考 https://blog.csdn.net/qq_32299035/article/details/104897710
