OC底层原理08 - objc_msgSend流程之快速查找
2020-12-16 本文已影响0人
H雷610
OC runtime运行时
在探索objc_msgSend时，我们需要先了解OC的runtime机制
runtime简介
runtime称为运行时，它区别于编译时
-
编译时：是把源代码翻译成机器能识别的代码的过程，主要是对语言进行最基本的检查报错，即词法分析、语法分析等，是一个静态的阶段 -
运行时：是代码跑起来，被装载到内存中的过程，如果此时出错，则程序会崩溃，是一个动态阶段
runtime的使用有以下三种方式，其三种实现方法与编译层和底层的关系如图所示 - 通过
Objective-C Code代码，例如[person sayHello] - 通过
Framework&Serivce方法，例如isKindOfClass、isMemberOfClass、NSSelectorFromString - 通过
Runtime API，例如class_getInstanceSize
image.png
其中的compiler就是我们了解的编译器，即LLVM；runtime system library就是底层库
探索方法的本质
- 新建一个
HLPerson类并声明两个实例方法
@interface HLPerson : NSObject
- (void)sayHello;
- (void)sayGoodbye;
@end
@implementation HLPerson
- (void)sayHello {
NSLog(@"%s",__func__);
}
- (void)sayGoodbye {
NSLog(@"%s",__func__);
}
@end
- 在
main函数中初始化HLPerson并调用两个实例方法
int main(int argc, const char * argv[]) {
@autoreleasepool {
// insert code here...
HLPerson *person = [HLPerson alloc];
[person sayHello];
[person sayGoodbye];
}
return 0;
}
- 通过
clang将main.m文件编译成main.cpp文件，并找到main函数
int main(int argc, const char * argv[]) {
/* @autoreleasepool */ { __AtAutoreleasePool __autoreleasepool;
HLPerson *person = ((HLPerson *(*)(id, SEL))(void *)objc_msgSend)((id)objc_getClass("HLPerson"), sel_registerName("alloc"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayHello"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayGoodbye"));
}
return 0;
}
通过上述代码可以看出，方法的本质就是objc_msgSend消息发送
验证方法的本质就是objc_msgSend消息发送
- 导入头文件
#import <objc/message.h> - 将
target --> Build Setting-->搜索msg-- 将enable strict checking of obc_msgSend calls由YES改为NO，将严厉的检查机制关掉，否则objc_msgSend的参数会报错 - 添加代码
HLPerson *person = [HLPerson alloc];
[person sayHello];
objc_msgSend(person, sel_registerName(@"sayHello"));
- 运行项目，查看打印
image.png
打印结果相同，说明[person sayHello]等价于objc_msgSend(person, sel_registerName(@"sayHello"))
调用父类方法
- 新建一个
HLTeacher类继承于HLPerson类，重写sayGoodbye方法
@interface HLTeacher : HLPerson
@end
@implementation HLTeacher
- (void)sayGoodbye {
NSLog(@" teacher -- %s",__func__);
}
@end
- 在
main.m文件中，创建一个teacher对象，并调用sayGoodbye方法；使用objc_msgSendSuper调用sayGoodbye方法
HLTeahcer *teacher = [HLTeahcer alloc];
[teacher sayGoodbye];
struct objc_super hlSuper;
hlSuper.receiver = teacher; // 消息的接收者
hlSuper.super_class = [HLPerson class]; // 告诉父类是谁
//消息的接受者还是自己 - 父类 - 请你直接找我的父亲
objc_msgSendSuper(&hlSuper, sel_registerName("sayGoodbye"));
- 运行项目，查看打印
image.png
objc_msgSendSuper(person, sel_registerName(@"sayGoodbye"))直接调用了父类的sayGoodbye方法
总结
-
方法的本质：发送消息 -
OC调用方法等价于runtime中objc_msgSend和objc_msgSendSuper消息发送
问题
objc_msgSend是怎样找到对应的方法呢？即sel如何找到对应imp
探索objc_msgSend
在objc4源码中我们会发现objc_msgSend是使用汇编实现的，汇编主要的特性是：
-
速度快：汇编更容易被机器识别。 -
方法参数的动态性：汇编调用函数时传递的参数是不确定的，那么发送消息时，直接调用一个函数就可以发送所有的消息。
objc_msgSend分析
bjc4-781源码中，搜索objc_msgSend，由于我们日常开发的都是架构是arm64，所以需要在arm64.s后缀的文件中查找objc_msgSend源码实现
// 消息发送 -- 汇编入口 -- objc_msgSend 主要是拿到接收者的 isa 信息
ENTRY _objc_msgSend
// 无窗口
UNWIND _objc_msgSend, NoFrame
// p0 和空对比，即判断接收者是否存在，其中 p0 是 objc_msgSend 的第一个参数 即消息接收者 receiver
cmp p0, #0 // nil check and tagged pointer check
#if SUPPORT_TAGGED_POINTERS
// 小对象流程
b.le LNilOrTagged // (MSB tagged pointer looks negative)
#else
// 消息接收者为空，返回空
b.eq LReturnZero
#endif
// 消息接收者不为空
// 取出 isa，存入 p13
ldr p13, [x0] // p13 = isa
// p16 根据isa p13获取到 Class
GetClassFromIsa_p16 p13 // p16 = class
LGetIsaDone:
// calls imp or objc_msgSend_uncached
// 如果有isa，走到 CacheLookup 即缓存查找流程，也就是所谓的sel-imp快速查找流程
CacheLookup NORMAL, _objc_msgSend
#if SUPPORT_TAGGED_POINTERS
LNilOrTagged:
// 空值校验，为空则返回空
b.eq LReturnZero // nil check
// tagged
adrp x10, _objc_debug_taggedpointer_classes@PAGE
add x10, x10, _objc_debug_taggedpointer_classes@PAGEOFF
ubfx x11, x0, #60, #4
ldr x16, [x10, x11, LSL #3]
adrp x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGE
add x10, x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGEOFF
cmp x10, x16
b.ne LGetIsaDone
// ext tagged
adrp x10, _objc_debug_taggedpointer_ext_classes@PAGE
add x10, x10, _objc_debug_taggedpointer_ext_classes@PAGEOFF
ubfx x11, x0, #52, #8
ldr x16, [x10, x11, LSL #3]
b LGetIsaDone
// SUPPORT_TAGGED_POINTERS
#endif
LReturnZero:
// x0 is already zero
mov x1, #0
movi d0, #0
movi d1, #0
movi d2, #0
movi d3, #0
ret
END_ENTRY _objc_msgSend
主要流程如下：
image.png
CacheLookup 缓存查找汇编源码
在objc-msg-arm64.s文件中找到.macro CacheLookup
.macro CacheLookup
//
// Restart protocol:
//
// As soon as we're past the LLookupStart$1 label we may have loaded
// an invalid cache pointer or mask.
//
// When task_restartable_ranges_synchronize() is called,
// (or when a signal hits us) before we're past LLookupEnd$1,
// then our PC will be reset to LLookupRecover$1 which forcefully
// jumps to the cache-miss codepath which have the following
// requirements:
//
// GETIMP:
// The cache-miss is just returning NULL (setting x0 to 0)
//
// NORMAL and LOOKUP:
// - x0 contains the receiver
// - x1 contains the selector
// - x16 contains the isa
// - other registers are set as per calling conventions
//
LLookupStart$1:
// p1 = SEL, p16 = isa
// isa 平移16字节得到 cache_t，cache首地址是mask_buckets
ldr p11, [x16, #CACHE] // p11 = mask|buckets
// 64位真机
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
// 获取 buckets： p11 & 0x0000ffffffffffff 得到后48位 即 buckets
and p10, p11, #0x0000ffffffffffff // p10 = buckets
// 获取 hash 搜索下标：逻辑右移48位 得到 mask；然后p1 & mask给p12 得到hash存储的key
and p12, p1, p11, LSR #48 // x12 = _cmd & mask
// 非64位真机
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
and p10, p11, #~0xf // p10 = buckets
and p11, p11, #0xf // p11 = maskShift
mov p12, #0xffff
lsr p11, p12, p11 // p11 = mask = 0xffff >> p11
and p12, p1, p11 // x12 = _cmd & mask
#else
#error Unsupported cache mask storage for ARM64.
#endif
// p12是获取到的下标，然后逻辑左移4位，再由p10(buckets)平移，得到对应的bucket保存到p12中
add p12, p10, p12, LSL #(1+PTRSHIFT)
// p12 = buckets + ((_cmd & mask) << (1+PTRSHIFT))
// 将p12属性 imp 和 sel 分别赋值为 p17 和 p9
ldp p17, p9, [x12] // {imp, sel} = *bucket
// 判断当前 bucket 的 sel 和传入的 sel 是否相等
1: cmp p9, p1 // if (bucket->sel != _cmd)
// 如果不相同，则跳入2f
b.ne 2f // scan more
// 如果相同直接返回imp
CacheHit $0 // call or return imp
// 没有找到 进入2f
2: // not hit: p12 = not-hit bucket
CheckMiss $0 // miss if bucket->sel == 0
// 如果p12 == p10，说明 p12 指针已经到了 buckets的 首地址了。
cmp p12, p10 // wrap if bucket == buckets
// 如果相等 跳入3f
b.eq 3f
// 从x12（即p12 buckets首地址）- 实际需要平移的内存大小BUCKET_SIZE，得到得到第二个bucket元素，imp-sel分别存入p17-p9，即向前查找
ldp p17, p9, [x12, #-BUCKET_SIZE]! // {imp, sel} = *--bucket
// 跳转至 1b，继续对比 sel 与 cmd
b 1b // loop
3: // wrap: p12 = first bucket, w11 = mask
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
// 将p12的指针指到buckets的最后一个元素
add p12, p12, p11, LSR #(48 - (1+PTRSHIFT))
// p12 = buckets + (mask << 1+PTRSHIFT)
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
add p12, p12, p11, LSL #(1+PTRSHIFT)
// p12 = buckets + (mask << 1+PTRSHIFT)
#else
#error Unsupported cache mask storage for ARM64.
#endif
// Clone scanning loop to miss instead of hang when cache is corrupt.
// The slow path may detect any corruption and halt later.
// 然后在继续查找，直到找到或者再次 bucket 与 buckets再次相等，跳出循环。
// 拿到x12（即p12）bucket中的 imp-sel 分别存入 p17-p9
ldp p17, p9, [x12] // {imp, sel} = *bucket
// 判断当前 bucket 的 sel 和传入的 sel 是否相等
1: cmp p9, p1 // if (bucket->sel != _cmd)
// 如果不相同，则跳入2f
b.ne 2f // scan more
// 如果相同，则直接返回 imp
CacheHit $0 // call or return imp
2: // not hit: p12 = not-hit bucket
CheckMiss $0 // miss if bucket->sel == 0
// 判断p12（下标对应的bucket） 是否 等于 p10（buckets数组第一个元素）-- 表示前面已经没有了，但是还是没有找到
cmp p12, p10 // wrap if bucket == buckets
// 如果等于，跳转至第3步
b.eq 3f
// 从x12（即p12 buckets首地址）- 实际需要平移的内存大小BUCKET_SIZE，得到得到第二个bucket元素，imp-sel分别存入p17-p9，即向前查找
ldp p17, p9, [x12, #-BUCKET_SIZE]! // {imp, sel} = *--bucket
// 跳转至第1步，继续对比 sel 与 cmd
b 1b // loop
LLookupEnd$1:
LLookupRecover$1:
3: // double wrap
// 结束循环
JumpMiss $0
.endmacro
方法解析
主要流程可以分为以下几步
- 通过
isa首地址平移16字节（在objc_class中，首地址距离cache正好16字节，即isa占8字节，superClass占8字节），获取cache，cache中高16位存mask，低48位存buckets，即p11 = cache
ldr p11, [x16, #CACHE]
- 从
cache中分别取出buckets和mask，并由mask根据哈希算法计算出哈希下标(只看64位真机)
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
2.1. 通过cache和掩码（即0x0000ffffffffffff）的&运算，将高16位 mask抹零，得到buckets指针地址，即p10 = buckets
and p10, p11, #0x0000ffffffffffff // p10 = buckets
2.2. 将cache右移48位，得到mask，即p11 = mask， 将objc_msgSend的参数p1（即第二个参数_cmd）& mask，通过哈希算法，得到需要查找存储sel-imp的bucket下标index，即p12 = index = _cmd & mask
and p12, p1, p11, LSR #48 // x12 = _cmd & mask
因为在存储sel-imp时，也是通过同样哈希算法计算哈希下标进行存储，所以读取也需要通过相同的方式读取，如下所示
image.png
- 根据所得的哈希下标
index和buckets首地址，取出哈希下标对应的bucket
add p12, p10, p12, LSL #(1+PTRSHIFT)
// p12 = buckets + ((_cmd & mask) << (1+PTRSHIFT))
- 其中
PTRSHIFT等于3，左移4位（即2^4 = 16字节）的目的是计算出一个bucket实际占用的大小，结构体bucket_t中sel占8字节，imp占8字节 - 根据计算的哈希下标
index乘以单个bucket占用的内存大小，得到目标bucket首地址在实际内存中的偏移量 - 通过
首地址 + 实际偏移量，获取哈希下标index对应的bucket
- 根据获取的
bucket，取出其中的imp存入p17，即p17 = imp，取出sel存入p9，即p9 = sel
ldp p17, p9, [x12] // {imp, sel} = *bucket
- 第一次递归循环
比较获取的bucket中sel与objc_msgSend的第二个参数的_cmd(即p1)是否相等
1: cmp p9, p1 // if (bucket->sel != _cmd)
5.1 如果相等，则直接跳转至CacheHit，即缓存命中，返回imp
CacheHit $0 // call or return imp
5.2.1 如果不相等，跳转至2f
b.ne 2f // scan more
5.2.2 由于汇编中的查找是向上查找，所以p12-1获取到上一个bucket指针。如果当前p12 bucket与buckets的首地址(第一个元素) 相等，那么就直接跳入3f；如果当前bucket 不等于 buckets的第一个元素，则继续向前查找，进入第一次递归循环；如果一直都找不到，直接跳转至CheckMiss，因为$0是normal，会跳转至__objc_msgSend_uncached，即进入慢速查找流程
2: // not hit: p12 = not-hit bucket
CheckMiss $0 // miss if bucket->sel == 0
cmp p12, p10 // wrap if bucket == buckets
b.eq 3f
ldp p17, p9, [x12, #-BUCKET_SIZE]! // {imp, sel} = *--bucket
b 1b // loop
- 第二次递归循环：重复
第五步的操作，与第五步中唯一区别是，如果当前的bucket还是等于buckets的第一个元素，则直接跳转至JumpMiss，此时的$0是normal，也是直接跳转至__objc_msgSend_uncached，即进入慢速查找流程
objc_msgSend 流程图
未命名文件(1).png
