SAS编程：Proc SQL生成宏变量时INTO子句的使用

在日常的编程中，为了方便调用某些值，一个简便的方法是将这些值赋值到宏变量中。给宏变量赋值，Data步和Proc步都能可以实现，不过从操作灵活性上讲，Proc步要更胜一筹。Proc步生成宏变量就需要用到INTO子句，下面来具体介绍一下INTO子句如何使用。

INTO子句的作用是，将PROC SQL生成的值赋值给宏变量。

语法

我们来看一下INTO子句的具体语法：

INTO : macro-variable-specification-1 <, : macro-variable-specification-2 ...>

macro-variable-specification，宏变量的说明，是要创建的一个或多个宏变量的名称，并且在每个宏变量名称前都需要添加一个冒号:。如果不添加冒号，程序运行时会报错。

macro-variable-specification的形式

INTO语句宏变量的命名有3种形式：

1. into : macro-variable（指定一个或多个宏变量）
2. into : macro-variable-1 − : macro-variable-n <NOTRIM> （指定一个宏变量序列）
3. into : macro-variable SEPARATED BY 'characters ' <NOTRIM> （指定一个宏变量来保存一列的所有值）

下面我来介绍每种方式的语法和具体的代码示例，使用的示例数据集是SASHELP.BASEBALL, 为了方便演示，我只选取数据集前4行的记录，先看一下数据集具体的内容：

data baseball;
  set sashelp.baseball (obs =4);
run;

Baseball

下面具体看每一种命名方式：

1、指定一个或多个宏变量（into : macro-variable）

使用这种命名方式，赋值给宏变量的值的前置和后置空格都会被保留。如果想要移除前置或后置空格，需要自行对所引用的值进行函数处理。如果要命名多个宏变量，各个宏变量名称之前都需要添加冒号:，并且名称之前都要有逗号,间隔。同时，也要注意，这种命名方式只是选取变量的一条记录赋值给宏变量。如果所选变量有多条记录，并且不经过筛选的话，默认是选取第一条记录进行赋值。

赋值代码示例：

proc sql noprint;
 select name, team
   into :name, :team
   from baseball;
quit;

%put &name;
%put &team;

宏变量的值如下：

&name &team

从结果中，我们可以看到，变量name、team的第一条记录都被赋值到宏变量中了。

2、指定一个宏变量序列（into : macro-variable-1 − : macro-variable-n <NOTRIM>）

使用这种命名方式，赋值给宏变量的值的前置和后置空格都会被自动移除。如果项目要保留值的前置和后置空格，就需要在每个元素后面添加NOTRIM选项。如果有多个元素存在，只需要对需要保留空格的那个元素使用NOTRIM选项。序列中有多少数目的宏变量名，就会有同样数目的变量记录赋值到对应宏变量中。

赋值代码示例：

proc sql noprint;
 select name, team
   into :name1- :name4 notrim, :team1 - :team3
   from baseball;
quit;

考虑到有多个宏变量，我们利用SAS字典的值来查看宏变量的值：

%symdel name team;

proc sql noprint;
  create table test as
  select *
  from dictionary.macros
  where index(name, "NAME") or index(name, "TEAM")
  ;
quit;

输出结果如下：

Output2

当用宏变量序列来保存变量的值时，可以保存多个变量值。

3、指定一个宏变量来保存一列的所有值（into : macro-variable SEPARATED BY 'characters ' <NOTRIM>）

使用这种命名方式，列表中的值将会被一个或多个字符分隔。赋值给宏变量的值的前置和后置空格都会被自动移除。如果项目要保留值的前置和后置空格，也还是需要使用NOTRIM选项。

这种命名方式便于建立一项事物的集合，比如，实现变量可能取值的汇总：

proc sql noprint;
  select distinct name
    into :names separated by ','
    from baseball;
quit;

%put &names;

宏变量的值如下：

Output 3.1

再比如，建立批量命名语句：

proc sql noprint;
  select strip(name)||" = "||strip(name)||"_new" into :rename separated by " "
  from dictionary.columns
  where libname="WORK" and memname="BASEBALL";
quit;

%put &rename.;

data baseball_new;
  set baseball;
  rename &rename.;
run;

Output 3.2.1 Output 3.2.2

再比如，只保留数据集中字符型变量：

proc sql noprint;
  select name into :keepnames separated by " "
  from dictionary.columns
  where libname="WORK" and memname="BASEBALL" and type="char";
quit;

%put &keepnames.;

data baseball1;
  set baseball;
  keep &keepnames.;
run;

Output 3.3.1 Output3.3.2

熟悉INTO子句的用法后，可以根据根据任务的需求自由发挥。

以上。

若有疑问，欢迎评论区交流！