程序员

OC-关联对象AssociatedObject

2018-06-07  本文已影响20人  东方_未明

关联对象

前言

我们都知道ARC环境下, 在一个类中声明一个属性@property (nonatomic, assign) int age;, 系统类似的帮我们生成如下代码:

  1. 生成下划线的成员变量
  2. 生成setter, getter方法的声明
  3. 生成setter, getter方法的实现
@interface Person : NSObject
{
    int _age;
}

- (void)setAge:(int)age;
- (int)age;

@end


@implementation Person

- (void)setAge:(int)age
{
    _age = age;
}

- (int)age
{
    return _age;
}
@end

Category中添加属性

在category中添加属性, 系统只会做一件事情, 生成setter, getter方法的声明.
我们知道category中不可以添加实例变量, 因为category是一个结构体, 它只可以添加对象/类方法, 协议, 属性

struct _category_t {
    const char *name;
    struct _class_t *cls;
    const struct _method_list_t *instance_methods;
    const struct _method_list_t *class_methods;
    const struct _protocol_list_t *protocols;
    const struct _prop_list_t *properties;
};

如果要让我们实现可以类似的可以添加实例变量的效果, 那该如何做呢?

关联对象的原理

实现关联对象技术的核心对象有:
AssociationsManager
AssociationsHashMap
ObjectAssociationMap
ObjcAssociation
可以通过苹果的开源代码 objc4: objc-references.mm //引用

class AssociationsManager {
    static AssociationsHashMap *_map;
}

class AssociationsHashMap: public unordered_map<disguised_ptr_t, ObjectAssociationMap>

class ObjectAssociationMap: public std::map <void *, ObjcAssociation>

class ObjcAssociation {
    uintptr_t _policy;
    id _value;
}

举例说明:

@implementation Person (Test)

- (void)setAge:(int)age
{
    objc_setAssociatedObject(self, @selector(age), @(age), OBJC_ASSOCIATION_ASSIGN);
}

- (void)setName:(NSString *)name
{
    objc_setAssociatedObject(self, @selector(name), name, OBJC_ASSOCIATION_COPY_NONATOMIC);
}

@end

上面的代码给Person实例对象关联的两个值(age和name), 底层上是由全局的AssociationsManager管理, AssociationsManager中有一个AssociationsHashMap(字典), 其中以(姑且认为)person为键, AssociationsHashMap(字典)为值. AssociationsHashMap(字典)中以关联值传入的key为键, 以ObjcAssociation对象为值, ObjcAssociation中包含内存策略和value值

开源代码如下:

// setter
void objc_setAssociatedObject(id object, const void *key, id value, objc_AssociationPolicy policy) {
    _object_set_associative_reference(object, (void *)key, value, policy);
}

void _object_set_associative_reference(id object, void *key, id value, uintptr_t policy) {
    // retain the new value (if any) outside the lock.
    ObjcAssociation old_association(0, nil);
    id new_value = value ? acquireValue(value, policy) : nil;
    {
        AssociationsManager manager;
        AssociationsHashMap &associations(manager.associations());
        // 传入的对象object, 经过DISGUISE(object)函数, 进行内存操作, 作为key
        disguised_ptr_t disguised_object = DISGUISE(object);
        if (new_value) { //如果
            // break any existing association.
            // 根据disguised_object, 找到该对象对应的AssociationsHashMap
            AssociationsHashMap::iterator i = associations.find(disguised_object);
            if (i != associations.end()) {
                // secondary table exists
                // 根据i->second找到ObjectAssociationMap的指针
                ObjectAssociationMap *refs = i->second;
                ObjectAssociationMap::iterator j = refs->find(key);
                if (j != refs->end()) {
                    //如果key有对应的`ObjcAssociation`, 则替换
                    old_association = j->second;
                    j->second = ObjcAssociation(policy, new_value);
                } else {
                    (*refs)[key] = ObjcAssociation(policy, new_value);
                }
            } else { //如果key没有对应的`ObjcAssociation`, 则创建新的key, ObjcAssociation键值对
                // create the new association (first time).
                ObjectAssociationMap *refs = new ObjectAssociationMap;
                associations[disguised_object] = refs;
                (*refs)[key] = ObjcAssociation(policy, new_value);
                object->setHasAssociatedObjects();
            }
        } else {
            // setting the association to nil breaks the association.
            // 如果传入的value为nil值
            AssociationsHashMap::iterator i = associations.find(disguised_object);
            if (i !=  associations.end()) {
                ObjectAssociationMap *refs = i->second;
                ObjectAssociationMap::iterator j = refs->find(key);
                if (j != refs->end()) { //遍历该对象对应的字典中所有的ObjectAssociationMap, 进行抹除操作
                    old_association = j->second;
                    refs->erase(j); // 抹除
                }
            }
        }
    }
    // release the old value (outside of the lock).
    if (old_association.hasValue()) ReleaseValue()(old_association);
}


// getter
id objc_getAssociatedObject(id object, const void *key) {
    return _object_get_associative_reference(object, (void *)key);
}

id _object_get_associative_reference(id object, void *key) {
    id value = nil;
    uintptr_t policy = OBJC_ASSOCIATION_ASSIGN;
    {
        AssociationsManager manager;
        AssociationsHashMap &associations(manager.associations());
        disguised_ptr_t disguised_object = DISGUISE(object);
        AssociationsHashMap::iterator i = associations.find(disguised_object);
        if (i != associations.end()) {
            ObjectAssociationMap *refs = i->second;
            ObjectAssociationMap::iterator j = refs->find(key);
            if (j != refs->end()) {
                ObjcAssociation &entry = j->second;
                value = entry.value();
                policy = entry.policy();
                if (policy & OBJC_ASSOCIATION_GETTER_RETAIN) {
                    objc_retain(value);
                }
            }
        }
    }
    if (value && (policy & OBJC_ASSOCIATION_GETTER_AUTORELEASE)) {
        objc_autorelease(value);
    }
    return value;
}

总结:

1.关联对象并不是存储在被关联对象本身内存中
2.关联对象存储在全局的统一的一个AssociationsManager中
3.设置关联对象为nil, 就相当于移除关联对象
4.移除某个对象上的所有的关联对象 void objc_removeAssociatedObjects(id object)
5.如果某个person对象被销毁了, 则这个person对象所对应的ObjectAssociationMap字典也会被销毁
6.因为内存策略(objc_AssociationPolicy)中没有weak,

    Person *p = [[Person alloc] init];
        
    {
        Person *tmp = [[Person alloc] init];
        objc_setAssociatedObject(p, @"tmp", tmp, OBJC_ASSOCIATION_ASSIGN);
    }
    NSLog(@"%@", objc_getAssociatedObject(p, @"tmp"));
    // 上面代码会报错误 EXC_BAD_ACCESS, 坏内存地址访问, 因为使用的是OBJC_ASSOCIATION_ASSIGN的内存策略, 出了大括号tmp对象释放

如何设置关联值的时候使用weak策略呢?
iOS weak 关键字漫谈

- (void)setContext:(CDDContext*)object {
    id __weak weakObject = object;
    id (^block)() = ^{ return weakObject; };
    objc_setAssociatedObject(self, @selector(context), block, OBJC_ASSOCIATION_COPY);
}

- (CDDContext*)context {
    id (^block)() = objc_getAssociatedObject(self, @selector(context));
    id curContext = (block ? block() : nil);
    return curContext;
}
上一篇下一篇

猜你喜欢

热点阅读