Cocos2d-x中SimpleAudioEngine播放多个背

2016-09-04 本文已影响937人 qufl

前段时间，做小示例的时候偶然发现了个问题（也许是我没仔细了解过SimpleAudioEngine）：

使用SimpleAudioEngine来播放背景音乐A

然后音乐开始播放了，使用preloadBackgroundMusic加载音乐B
然后使用isBackgroundMusicPlaying来查询时，返回值为false
然后使用stopBackgroundMusic来关闭背景音乐时，发现根本关不掉啊

从操作可以看出来，出问题的关键就在于，播放背景音乐时，进行了另外一个背景音乐的预加载，然而SimpleAudioEngine中，背景不能同时存在多个。

既然出现了问题，那就来看看源码是怎么写的（cocos2d-x 3.10）。

背景音乐预加载的代码：

//audio/ios/SimpleAudioEngine.mm
void SimpleAudioEngine::preloadBackgroundMusic(const char* pszFilePath)
{
    // Changing file path to full path
    std::string fullPath = FileUtils::getInstance()->fullPathForFilename(pszFilePath);
    static_preloadBackgroundMusic(fullPath.c_str());
}

这个函数中，重点是第二句，调用了一个静态方法static_preloadBackgroundMusic来加载背景音乐文件。这个方法的源码：

//audio/ios/SimpleAudioEngine.mm
static void static_preloadBackgroundMusic(const char* pszFilePath)
{
    [[SimpleAudioEngine sharedEngine] preloadBackgroundMusic: [NSString stringWithUTF8String: pszFilePath]];
}

看来是调用了ObjC封装的接口，继续往下看：

//audio/ios/SimpleAudioEngine_objc.m
-(void) preloadBackgroundMusic:(NSString*) filePath {
    [am preloadBackgroundMusic:filePath];
}

这里看到，在Objc的接口中调用到了一个对象am的preloadBackgroundMusic方法。这个am，我们在这个.m文件的头部可以看到，它是一个CDAudioManager对象。所以这个对象里面的预加载是如何实现的呢：

//audio/ios/CDAudioManager.m
//Load background music ready for playing
-(void) preloadBackgroundMusic:(NSString*) filePath
{
    [self.backgroundMusic load:filePath];    
}

我们在这个文件中能够找到很多backgroundMusic，不能确定这里用到的是哪一个backgroundMusic。所以往上找，能看到它是属于
CDAudioManager，然后在头文件中可以看到：

@interface CDAudioManager : NSObject <CDLongAudioSourceDelegate, CDAudioInterruptProtocol, AVAudioSessionDelegate> {
    CDSoundEngine        *soundEngine;
    CDLongAudioSource    *backgroundMusic;
    NSMutableArray        *audioSourceChannels;
//....后面省略

其实，在这里我们就能看到问题了，这个CDAudioManager所持有的CDLongAudioSource引用只有一个，也就是说，表示我们的BackgroundMusic的资源对象只有一个。继续看这个CDLongAudioSource的load函数是怎么实现的：

-(void) load:(NSString*) filePath {
    //We have already loaded a file previously, check if we are being asked to load the same file
    if (state == kLAS_Init || ![filePath isEqualToString:audioSourceFilePath]) {
        CDLOGINFO(@"Denshion::CDLongAudioSource - Loading new audio source %@",filePath);
        //New file
        if (state != kLAS_Init) {
            [audioSourceFilePath release];//Release old file path
            [audioSourcePlayer release];//Release old AVAudioPlayer, they can't be reused
        }
        audioSourceFilePath = [filePath copy];
        NSError *error = nil;
        NSString *path = [CDUtilities fullPathFromRelativePath:audioSourceFilePath];
        audioSourcePlayer = [(AVAudioPlayer*)[AVAudioPlayer alloc] initWithContentsOfURL:[NSURL fileURLWithPath:path] error:&error];
        if (error == nil) {
            [audioSourcePlayer prepareToPlay];
            audioSourcePlayer.delegate = self;
            if (delegate && [delegate respondsToSelector:@selector(cdAudioSourceFileDidChange:)]) {
                //Tell our delegate the file has changed
                [delegate cdAudioSourceFileDidChange:self];
            }    
        } else {
            CDLOG(@"Denshion::CDLongAudioSource - Error initialising audio player: %@",error);
        }    
    } else {
        //Same file - just return it to a consistent state
        [self pause];
        [self rewind];
    }
    audioSourcePlayer.volume = volume;
    audioSourcePlayer.numberOfLoops = numberOfLoops;
    state = kLAS_Loaded;
}

在load函数中，如果新的Path与本对象中的属性audioSourceFilePath不同，而且之前已经加载过一个背景音乐，state不再是kLAS_Init，此时会释放并覆盖旧的audioSourcePlayer和audioSourceFilePath。

即使你先加载了音乐A，再加载音乐B，然后再重新加载一次音乐A，虽然Path与之前的A相同，但是控制的并不再是同一个对象，因为“旧”的引用总是会被丢弃。

到这里并没有结束，我们还需要确定一下，播放背景音乐的时候和这个audioSource有关。看看playBackgroundMusic的代码：

//audio/ios/SimpleAudioEngine.mm
void SimpleAudioEngine::playBackgroundMusic(const char* pszFilePath, bool bLoop)
{
    // Changing file path to full path
    std::string fullPath = FileUtils::getInstance()->fullPathForFilename(pszFilePath);
    static_playBackgroundMusic(fullPath.c_str(), bLoop);
}

同样，去找static_playBackgroundMusic方法：

static void static_playBackgroundMusic(const char* pszFilePath, bool bLoop)
{
    [[SimpleAudioEngine sharedEngine] playBackgroundMusic: [NSString stringWithUTF8String: pszFilePath] loop: bLoop];
}

然后找到Obj-c的接口：

-(void) playBackgroundMusic:(NSString*) filePath
{
    [am playBackgroundMusic:filePath loop:TRUE];
}
-(void) playBackgroundMusic:(NSString*) filePath loop:(BOOL) loop
{
    [am playBackgroundMusic:filePath loop:loop];
}

这里可以看到进行了一个重载，playBackgroundMusic方法的默认loop属性为true。然后继续看am中的代码：

-(void) playBackgroundMusic:(NSString*) filePath loop:(BOOL) loop
{
    [self.backgroundMusic load:filePath];

 if (loop) {
  [self.backgroundMusic setNumberOfLoops:-1];
 } else {
  [self.backgroundMusic setNumberOfLoops:0];
 }

 if (!willPlayBackgroundMusic || _mute) {
  CDLOGINFO(@"Denshion::CDAudioManager - play bgm aborted because audio is not exclusive or sound is muted");
  return;
 }

 [self.backgroundMusic play];
}

这里第一句就是调用CDLongAudioSource的load方法，也就是之前我们看到的preloadBakcgroundMusic函数中所做的操作。中间一段是进行loop设置，以及错误处理。最后调用了self.backgroundMusic（CDLongAudioSource）的play方法。

结论：
至始至终，SimpleAudioEngine中只持有了一个关于背景音乐的引用。所以，进行连续的preloadBackgroundMusic或者playBackgroundMusic，我们看到的现象都是丢失了对原来的背景音乐的控制（引用）。

使用SimpleAudioEngine播放背景音乐时，如果游戏中有多个场景，每个场景有不同的背景音乐，我们没有必要去一次preload所有的BackgroundMusic文件，注意每次播放背景音乐前进行判断，确保旧的背景音乐被停止。

关于SimpleAudioEngine的测试代码，从我的Github中可以看到。如有错误与不完整指出，还请小伙伴指出！

Cocos2d-x中SimpleAudioEngine播放多个背

猜你喜欢

热点阅读