Mojo::URL
2017-10-10 本文已影响17人
JSON_NULL
简介
use Mojo::URL;
# Parse
my $url = Mojo::URL->new('http://sri:foo@example.com:3000/foo?foo=bar#23');
say $url->scheme;
say $url->userinfo;
say $url->host;
say $url->port;
say $url->path;
say $url->query;
say $url->fragment;
# Build
my $url = Mojo::URL->new;
$url->scheme('http');
$url->host('example.com');
$url->port(3000);
$url->path('/foo/bar');
$url->query(foo => 'bar');
$url->fragment(23);
say "$url";
Mojo :: URL实现了RFC 3986，RFC 3987和统一资源定位器的URL标准的一个子集，支持IDNA和IRI。
属性
Mojo::URL实现了以下属性。
base
my $base = $url->base;
$url = $url->base(Mojo::URL->new);
设置或获取当前对象的“基对象”，“基对象”也是一个Mojo::URL对象。
"http://example.com/a/b?c"
Mojo::URL->new("/a/b?c")->base(Mojo::URL->new("http://example.com"))->to_abs;
fragment
my $fragment = $url->fragment;
$url = $url->fragment('♥mojolicious♥');
返回或设置当前Mojo::URL对象的fragment，也就是URL中#号后面的部分，有时也称作HASH。
# "yada"
Mojo::URL->new('http://example.com/foo?bar=baz#yada')->fragment;
host
my $host = $url->host;
$url = $url->host('127.0.0.1');
设置或获取当前Mojo::URL对象的主机名。
# "example.com"
Mojo::URL->new('http://sri:t3st@example.com:8080/foo')->host;
port
my $port = $url->port;
$url = $url->port(8080);
设置或获取当前Mojo::URL对象的端口号。
# "8080"
Mojo::URL->new('http://sri:t3st@example.com:8080/foo')->port;
scheme
my $scheme = $url->scheme;
$url = $url->scheme('http');
设置或获取当前Mojo::URL所使用的协议。
# "http"
Mojo::URL->new('http://example.com/foo')->scheme;
userinfo
my $info = $url->userinfo;
$url = $url->userinfo('root:♥');
设置或获取当前Mojo::URL对象的用户信息。
# "sri:t3st"
Mojo::URL->new('https://sri:t3st@example.com/foo')->userinfo;
方法
Mojo :: URL继承Mojo :: Base中的所有方法，并实现以下方法。
clone
my $url2 = $url->clone;
返回从当前Mojo::URL对象复制得到的新Mojo::URL对象。
host_port
my $host_port = $url->host_port;
$url = $url->host_port('example.com:8080');
获取或设置当前URL对象的主机名和端口号。如果不传参数用于获取主机名和端口号，则返回字符串表示的一个标准化的主机名和端口号。
# "xn--n3h.net:8080"
Mojo::URL->new('http://?.net:8080/test')->host_port;
# "example.com"
Mojo::URL->new('http://example.com/test')->host_port;
ihost
my $ihost = $url->ihost;
$url = $url->ihost('xn--bcher-kva.ch');
返回或设置以punycode格式编码的主机名。
# "xn--n3h.net"
Mojo::URL->new('http://?.net')->ihost;
# "example.com"
Mojo::URL->new('http://example.com')->ihost;
is_abs
my $bool = $url->is_abs;
检查当前Mojo::URL对象是否是绝对URL。
# True
Mojo::URL->new('http://example.com')->is_abs;
Mojo::URL->new('http://example.com/test/index.html')->is_abs;
# False
Mojo::URL->new('test/index.html')->is_abs;
Mojo::URL->new('/test/index.html')->is_abs;
Mojo::URL->new('//example.com/test/index.html')->is_abs;
new
my $url = Mojo::URL->new;
my $url = Mojo::URL->new('http://127.0.0.1:3000/foo?f=b&baz=2#foo');
构造新的Mojo::URL对象，如果传了参数，则把参数当成URL进行解析。
parse
$url = $url->parse('http://127.0.0.1:3000/foo/bar?fo=o&baz=23#foo');
解析相对或绝对URL。
# "/test/123"
$url->parse('/test/123?foo=bar')->path;
# "example.com"
$url->parse('http://example.com/test/123?foo=bar')->host;
# "sri@example.com"
$url->parse('mailto:sri@example.com')->path;
password
my $password = $url->password;
获取URL里userinfo中的密码信息。
# "s3cret"
Mojo::URL->new('http://isabel:s3cret@mojolicious.org')->password;
# "s:3:c:r:e:t"
Mojo::URL->new('http://isabel:s:3:c:r:e:t@mojolicious.org')->password;
path
my $path = $url->path;
$url = $url->path('foo/bar');
$url = $url->path('/foo/bar');
$url = $url->path(Mojo::Path->new);
获取或设置当前URL的“路径”，如果为获取则默认返回Mojo::Path对象。
如果传了一个参数则为设置“路径”，此时相当于是Mojo::Path对象的marge方法被调用。
# "perldoc"
Mojo::URL->new('http://example.com/perldoc/Mojo')->path->parts->[0];
# "/perldoc/DOM/HTML"
Mojo::URL->new('http://example.com/perldoc/Mojo')->path->merge('DOM/HTML');
# "http://example.com/DOM/HTML"
Mojo::URL->new('http://example.com/perldoc/Mojo')->path('/DOM/HTML');
# "http://example.com/perldoc/DOM/HTML"
Mojo::URL->new('http://example.com/perldoc/Mojo')->path('DOM/HTML');
# "http://example.com/perldoc/Mojo/DOM/HTML"
Mojo::URL->new('http://example.com/perldoc/Mojo/')->path('DOM/HTML');
path_query
my $path_query = $url->path_query;
获取当前URL对象的path和query信息，返回的是一个标准化后的path和query信息。
# "/test?a=1&b=2"
Mojo::URL->new('http://example.com/test?a=1&b=2')->path_query;
# "/"
Mojo::URL->new('http://example.com/')->path_query;
protocol
my $proto = $url->protocol;
返回当前URL对象的标准化的协议。
# "http"
Mojo::URL->new('HtTp://example.com')->protocol;
query
my $query = $url->query;
$url = $url->query([merge => 'with']);
$url = $url->query({append => 'to'});
$url = $url->query(replace => 'with');
$url = $url->query('a=1&b=2');
$url = $url->query(Mojo::Parameters->new);
获取或设置当前URL对象的query（查询字符串）。
当不传参数时返回的是一个已经解析过的Mojo::Parameters对象。
当传一个参数时，参数的类型可以是hashref，arrayref，Mojo:Parameters对象和字符串。当然这个方法还可以接收一个参数列表，但需要保证参数列表中参数的个数为偶数。当参数类型为arrayref时相当于调用了Mojo::Parameters的merge方法；当参数类型为hashref时相当于调用了Mojo::Parameters的append方法；当参数为列表、字符串或Mojo::Parameters对象时，则会清空原有query使用参数中的内容重新构建。
# "2"
Mojo::URL->new('http://example.com?a=1&b=2')->query->param('b');
# "a=2&b=2&c=3"
Mojo::URL->new('http://example.com?a=1&b=2')->query->merge(a => 2, c => 3);
# "http://example.com?a=2&c=3"
Mojo::URL->new('http://example.com?a=1&b=2')->query(a => 2, c => 3);
# "http://example.com?a=2&a=3"
Mojo::URL->new('http://example.com?a=1&b=2')->query(a => [2, 3]);
# "http://example.com?a=2&b=2&c=3"
Mojo::URL->new('http://example.com?a=1&b=2')->query([a => 2, c => 3]);
# "http://example.com?b=2"
Mojo::URL->new('http://example.com?a=1&b=2')->query([a => undef]);
# "http://example.com?a=1&b=2&a=2&c=3"
Mojo::URL->new('http://example.com?a=1&b=2')->query({a => 2, c => 3});
to_abs
my $abs = $url->to_abs;
my $abs = $url->to_abs(Mojo::URL->new('http://example.com/foo'));
当前URL是一个相对URL，返回一个新的Mojo::URL对象，并且使用base方法提供的基url或通过参数传递一个基url把返回的新的Mojo::URL对象处理为一个绝对URL。
# "http://example.com/foo/baz.xml?test=123"
Mojo::URL->new('baz.xml?test=123')->to_abs(Mojo::URL->new('http://example.com/foo/bar.html'));
# "http://example.com/baz.xml?test=123"
Mojo::URL->new('/baz.xml?test=123')->to_abs(Mojo::URL->new('http://example.com/foo/bar.html'));
# "http://example.com/foo/baz.xml?test=123"
Mojo::URL->new('//example.com/foo/baz.xml?test=123')->to_abs(Mojo::URL->new('http://example.com/foo/bar.html'));
to_string
my $str = $url->to_string;
将url转换为字符串，注：出于安全考虑，返回的结果中不包含userinfo信息。
# "http://mojolicious.org"
Mojo::URL->new->scheme('http')->host('mojolicious.org')->to_string;
# "http://mojolicious.org"
Mojo::URL->new('http://daniel:s3cret@mojolicious.org')->to_string;
to_unsafe_string
my $str = $url->to_unsafe_string;
将当前对象转换为字符串，与to_string的区别是，这个方法返回的结果中包含userinfo信息。
# "http://daniel:s3cret@mojolicious.org"
Mojo::URL->new('http://daniel:s3cret@mojolicious.org')->to_unsafe_string;
username
my $username = $url->username;
获取URL里userinfo中的用户名信息。
# "isabel"
Mojo::URL->new('http://isabel:s3cret@mojolicious.org')->username;
重载的运算符
bool
my $bool = !!$url;
永远返回true。
stringify
my $str = "$url";
相当于调用了to_string方法。
