教程很多，随便列两个，强烈推荐学起来，没有python基础也可以搞定
参考1
参考2
Snakemake搭建生信分析流程-简介
snakemake使用笔记
[转]snakemake--我最喜欢的流程管理工具
主要需要一个snakefile和包含参数信息的config.yaml文件，所以需要编辑这两个文件，运行的时候只要把它们丢到数据所在的目录，使用以下代码运行就行了。

#!/bin/bash
#SBATCH --job-name=sbatch_rna_flow
#SBATCH --time=40:00:00
#SBATCH --cpus-per-task=20
#SBATCH --mem=60g
module load snakemake singularity
ml python/3.6
snakemake  -j 3 --use-singularity 

运行前建议使用

snakemake -np

去伪运行一下看看有没有错误在正式运行，这个习惯要保持。
如果因为运行出错导致lock可以用snakemake --unlock 解决

我使用的是SLURM递交系统，其他的可以用conda进行管理，老习惯，直接上代码，希望能够有所启发

PE (paired end) RNA-seq

snakefile

shell.executable("/bin/bash")
configfile: "./config.yaml"

(SAMPLES,READS,) = glob_wildcards("fastq/{sample}_{read}.fastq.gz")
READS=["1","2"]

rule all:
    input:
        "4_final_counts/final_counts.txt"

rule fastqc:
    input:
        "fastq/{sample}_1.fastq.gz",
        "fastq/{sample}_2.fastq.gz"
    output:
        "1_initial_qc/{sample}/{sample}_1_fastqc.zip",
        "1_initial_qc/{sample}/{sample}_2_fastqc.zip",
        "1_initial_qc/{sample}/{sample}_1_fastqc.html",
        "1_initial_qc/{sample}/{sample}_2_fastqc.html"
    log:
        "log/{sample}_fastqc"
    shell:
        """
        ml fastqc
        fastqc -o 1_initial_qc/{wildcards.sample} --noextract {input[0]} {input[1]} 2> {log}
        """

rule fastp:
    input:
        fwd="fastq/{sample}_1.fastq.gz",
        rev="fastq/{sample}_2.fastq.gz"
    output:
        fwd="2_fastp_output/{sample}_1_good.fq.gz",
        rev="2_fastp_output/{sample}_2_good.fq.gz",
        html="2_fastp_output/{sample}.html",
        json="2_fastp_output/{sample}.json"
    log:
        "log/{sample}_fastp"
    shell:
        """
        ml fastp
        fastp -w 10 -h {output[html]} -j  {output[json]} -i {input[fwd]} -I {input[rev]} -o {output[fwd]} -O {output[rev]} 2> {log}
        """

rule HISAT2:
    input:
        "2_fastp_output/{sample}_1_good.fq.gz",
        "2_fastp_output/{sample}_2_good.fq.gz"
    output:
        "3_HISAT2_aligned/{sample}.bam",
        "3_HISAT2_aligned/{sample}.bam.bai"
    params: "3_HISAT2_aligned/{sample}.bam"
    log:
        "log/{sample}_HISAT2"
    shell:
        """
        ml hisat
        ml samtools
        ml sambamba
        hisat2 -p {config[threads]} -x {config[index]} \
        -1 {input[0]} -2 {input[1]} \
        --no-mixed --no-discordant | sambamba view -t {config[threads]} --sam-input --format=bam /dev/stdin | \
        samtools sort -@ {config[threads]} > {params}
        samtools index -@ {config[threads]} {params}
        """

rule featureCounts:
    input:
        expand("3_HISAT2_aligned/{sample}.bam", sample=SAMPLES)
    output:
        "4_final_counts/final_counts.txt",
        "4_final_counts/final_counts.txt.summary"
    log:
        "log/featurecounts.log"
    shell:
        """ 
        ml subread
        ls 3_HISAT2_aligned/*bam | xargs featureCounts -a {config[gtf]} -o {output[0]} \
        -s {config[strand]} -T {config[threads]} -t exon -g gene_id 2> {log}
        """

config.yaml

gtf: "/gtf/gencode.v33.annotation.gtf"
index: "/hg38/grch38_p13/genome"
threads: 5
###featurecounts strand information 1 notrand 2 trand 0 unknown,depend on the library kit
strand: 2

SE RNAseq

snakefile

shell.executable("/bin/bash")
configfile: "./config.yaml"

(SAMPLES,) = glob_wildcards("fastq/{sample}.fastq.gz")


rule all:
    input:
        "4_final_counts/final_counts.txt"

rule fastqc:
    input:
        "fastq/{sample}.fastq.gz",
    output:
        "1_initial_qc/{sample}/{sample}.fastqc.zip",
        "1_initial_qc/{sample}/{sample}.fastqc.html",
    log:
        "log/{sample}_fastqc"
    shell:
        """
        ml fastqc
        fastqc -o 1_initial_qc/{wildcards.sample} --noextract {input[0]} 2> {log}
        """

rule fastp:
    input:
        "fastq/{sample}.fastq.gz"
    output:
        fwd="2_fastp_output/{sample}.good.fq.gz",
        html="2_fastp_output/{sample}.html",
        json="2_fastp_output/{sample}.json"
    log:
        "log/{sample}_fastp"
    shell:
        """
        ml fastp
        fastp -w 10 -h {output[html]} -j  {output[json]} -i {input[0]} -o {output[fwd]}  2> {log}
        """

rule HISAT2:
    input:
        "2_fastp_output/{sample}.good.fq.gz",
    output:
        "3_HISAT2_aligned/{sample}.bam",
        "3_HISAT2_aligned/{sample}.bam.bai"
    params: "3_HISAT2_aligned/{sample}.bam"
    log:
        "log/{sample}_HISAT2"
    shell:
        """
        ml hisat
        ml samtools
        ml sambamba
        hisat2 -p {config[threads]} -x {config[index]} \
        -U {input[0]} \
        --no-mixed --no-discordant | sambamba view -t {config[threads]} --sam-input --format=bam /dev/stdin | \
        samtools sort -@ {config[threads]} > {params}
        samtools index -@ {config[threads]} {params}
        """

rule featureCounts:
    input:
        expand("3_HISAT2_aligned/{sample}.bam", sample=SAMPLES)
    output:
        "4_final_counts/final_counts.txt",
        "4_final_counts/final_counts.txt.summary"
    log:
        "log/featurecounts.log"
    shell:
        """ 
        ml subread
        ls 3_HISAT2_aligned/*bam | xargs featureCounts -a {config[gtf]} -o {output[0]} \
        -s {config[strand]} -T {config[threads]} -t exon -g gene_id 2> {log}
        """

config.yaml

gtf: "/gtf/gencode.vM23.annotation.gtf"
index: "/grcm38/genome"
threads: 3
###featurecounts strand information 1 notrand 2 trand 0 unknown,depend on the library kit
strand: 0

轻松加easy，看个电影来收数据，注意控制好线程数否则内存爆表。

image.png