全国哀悼日期间App需要整体去彩色。采用如下方式实现。
先建立一个UIImageView的子类

UIImageView

用重写setImage的方法修改。

- (void)setImage:(UIImage *)image
{
    super.image = [self makeGrayImage:image];
}

在Xcode中查找所有用到UIImageView的地方，替换成你所建立的子类。（查找范围记得别选上pods部分，免得修改过多）
这样SDWebImage展示图片的方法，也会走setImage。能把所有图片都变灰。（button等可以以此类推）。

1.可用修改图片饱和度的方法修改

- (UIImage*)makeGrayImage:(UIImage*)image {
    //修改饱和度为0
    CIImage *beginImage = [CIImage imageWithCGImage:image.CGImage];
    CIFilter * filter = [CIFilter filterWithName:@"CIColorControls"];
    [filter setValue:beginImage forKey:kCIInputImageKey];
    //饱和度 0---2 默认为1
    [filter setValue:0 forKey:@"inputSaturation"];

    // 得到过滤后的图片
    CIImage *outputImage = [filter outputImage];
    // 转换图片, 创建基于GPU的CIContext对象
    CIContext *context = [CIContext contextWithOptions: nil];
    CGImageRef cgimg = [context createCGImage:outputImage fromRect:[outputImage extent]];
    UIImage *newImg = [UIImage imageWithCGImage:cgimg];
    // 释放C对象
    CGImageRelease(cgimg);
    return newImg;
}

优点：饱和度为0的过程就是图片去色的过程。适用所有图片不会对透明度有影响。
缺点：
1.内存占用较大。
2.从iOS10.4开始可以使用。
3.（会使用GPU）FPS暴涨，出现跳帧的现象。

2.可用灰度处理的方法修改

- (UIImage*)systemImageToGrayImage:(UIImage*)image{
    int width = image.size.width;
    int height = image.size.height;
    //第一步:创建颜色空间(说白了就是 开辟一块颜色内存空间)
    //图片灰度处理(创建灰度空间)
 
    CGColorSpaceRef colorRef = CGColorSpaceCreateDeviceGray();
    
    //第二步:颜色空间的上下文(保存图像数据信息)
    //参数1:内存大小(指向这块内存区域的地址)(内存地址)
    //参数2:图片宽
    //参数3:图片高
    //参数4:像素位数(颜色空间,例如:32位像素格式和RGB颜色空间,8位)
    //参数5:图片每一行占用的内存比特数
    //参数6:颜色空间
    //参数7:图片是否包含A通道(ARGB通道)
    CGContextRef context = CGBitmapContextCreate(nil, width, height, 8, 0, colorRef, kCGImageAlphaNone);
    
    //释放内存
    CGColorSpaceRelease(colorRef);
    if (context == nil) {
        return nil;
    }
    //第三步:渲染图片(绘制图片)
    //参数1:上下文
    //参数2:渲染区域
    //参数3:源文件(原图片)(说白了现在是一个C/C++的内存区域)
    CGContextDrawImage(context, CGRectMake(0, 0, width, height), image.CGImage);
    
    //第四步:将绘制颜色空间转成CGImage(转成可识别图片类型)
    CGImageRef grayImageRef = CGBitmapContextCreateImage(context);
    
    //第五步:将C/C++ 的图片CGImage转成面向对象的UIImage(转成iOS程序认识的图片类型)
    UIImage* dstImage = [UIImage imageWithCGImage:grayImageRef];
    
    //释放内存
    CGContextRelease(context);
    CGImageRelease(grayImageRef);
    return dstImage;
}

优点：
1.经过几次测试，内存占用比修改饱和度方法低5-10mb。
2.iOS10可以支持。
3.占用的帧率（FPS）比较低且稳定。
缺点：png的透明部分会变黑，（如果不对有透明部分的控件做操作，则没问题）。
备注：kCGImageAlphaNone改为kCGImageAlphaPremultipliedLast https://blog.csdn.net/jeffasd/article/details/78142067

3.使用OpenCV实现(多提供一种思路)

#import <opencv2/opencv.hpp>
#import <opencv2/imgcodecs/ios.h>
- (UIImage*)opencvToGrayImage:(UIImage *)image{
    //image源文件
    if (!image){
        return nil;
    }
    // 1.将iOS的UIImage转成c++图片（数据：矩阵）

    cv::Mat mat_image_gray;

    UIImageToMat(image, mat_image_gray);

    // 2. 将c++彩色图片转成灰度图片

    // 参数一：数据源

    // 参数二：目标数据

    // 参数三：转换类型

    cv::Mat mat_image_dst;

    cvtColor(mat_image_gray, mat_image_dst, cv::COLOR_BGRA2GRAY);

    // 3.灰度 -> 可显示的图片

    cvtColor(mat_image_dst, mat_image_gray, cv::COLOR_GRAY2BGR);

    // 4. 将c++处理之后的图片转成iOS能识别的UIImage

    return MatToUIImage(mat_image_gray);
}

缺点：
1.内存占用最多。
2.使用C++编译，与swift混编需要做很多工作。
3.导入库较大，需要修改的地方很多，不完善。