书名：代码本色：用编程模拟自然系统
作者：Daniel Shiffman
译者：周晗彬
ISBN：978-7-115-36947-5
目录

5.20　吸引和排斥行为

1、applyForce()函数

• Box2D的物体对象有一个applyForce()函数，如果我们要对物体施加引力，只需要根据引力公式（引力=G 质量1 质量2 / 距离的平方）计算出引力向量，然后把向量传入applyForce()函数。toxiclibs的VerletParticle类也有applyForce()函数，我们可以通过它将力作用在粒子上。

2、引力作用行为

• 然而，toxiclibs考虑得更为深远，它允许我们在粒子上设定一些常规力（我们称为“行为”），toxiclibs会根据这些设定自动计算和施加力。比如，如果我们将AttractionBehavior对象添加在一个粒子上，那么其他粒子都将受这个粒子的引力作用。

假如我们有一个粒子类（继承自VerletParticle类）。

Particle p = new Particle(new Vec2D(200,200));

• 创建完粒子对象后，我们让一个AttractionBehavior对象依附在这个粒子上。

float distance = 20;
float strength = 0.1;
AttractionBehavior behavior = new AttractionBehavior(p, distance, strength);

• 注意AttractionBehavior的构造函数有两个参数——distance和strength。distance代表引力的作用范围，在上面的实现中，只有20像素范围内的其他粒子才会受引力的作用。strength参数代表引力的强度。

• 最后，为了激活引力的作用，AttractionBehavior对象需要被添加进toxiclibs的物理世界。

physics.addBehavior(behavior);

这意味着只要其他粒子距离该粒子足够近，它们肯定会受到这个粒子的引力作用。

3、排斥行为

• 尽管toxiclibs不会处理碰撞，但你还是可以创建类似碰撞的效果，只需要将一个排斥行为添加到每个粒子上（这样一来，粒子之间就存在排斥作用）。让我们看看如何在粒子类中实现这一特性。

class Particle extends VerletParticle2D {
    float r;
    Particle (Vec2D loc) {
        super(loc);
        r = 4;
        physics.addBehavior(new AttractionBehavior(this,r*4,-1));　　每次创建粒子对象时，同
   }
  void display() {
      fill(255);
      stroke(255);
      ellipse(x,y,r*2,r*2);
    }
}

下面，我们将用toxiclibs重新实现引力程序，让整个窗口中的粒子都受单
个Attractor对象的吸引作用。

4、示例

示例代码5-13　引力/斥力

import toxi.geom.*;
import toxi.physics2d.*;
import toxi.physics2d.behaviors.*;

ArrayList<Particle> particles;
Attractor attractor;

VerletPhysics2D physics;

void setup () {
  size (640, 360);
  physics = new VerletPhysics2D ();
  physics.setDrag (0.01);
  
  particles = new ArrayList<Particle>();
  for (int i = 0; i < 50; i++) {
    particles.add(new Particle(new Vec2D(random(width),random(height))));
  }
  
  attractor = new Attractor(new Vec2D(width/2,height/2));
}


void draw () {
  background (255);  
  physics.update ();

  attractor.display();
  for (Particle p: particles) {
    p.display();
  }
  
  if (mousePressed) {
    attractor.lock();
    attractor.set(mouseX,mouseY);
  } else {
    attractor.unlock();
  }
}

5、运行结果