步骤

1. 在项目中添加JitPackUpload.gradle

注意:修改group='com.github.stepyen'为你自己的

JitPackUpload.gradle

apply plugin: 'com.github.dcendents.android-maven'

// 指定group，com.github.<用户名>，这里我默认填写的是我的github账号，请换成你自己的。
group='com.github.stepyen'

//---------------------------------------------


// 指定编码
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

tasks.withType(Javadoc) {
    options.encoding = 'UTF-8'
}

if (project.hasProperty("android")) { // Android libraries
    task sourcesJar(type: Jar) {
        classifier = 'sources'
        from android.sourceSets.main.java.srcDirs
    }

    task javadoc(type: Javadoc) {
        failOnError  false
        source = android.sourceSets.main.java.srcDirs
        classpath += project.files(android.getBootClasspath().join(File.pathSeparator))
    }
} else { // Java libraries
    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }
}

javadoc {
    options {
        encoding "UTF-8"
        charSet 'UTF-8'
        author true
        version true
        links "http://docs.oracle.com/javase/7/docs/api"
    }
}

// 制作文档(Javadoc)
task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives javadocJar
    archives sourcesJar
}

2. 在要发布的lib下引用JitPackUpload.gradle

apply plugin: 'com.android.library'
// 添加  
apply from: '../JitPackUpload.gradle'

3. 上传项目到Github上

4. 项目打包为release包

image image

5. 登录jitpack官网

填写项目链接并点击Look Up,之后点击Get it生成

6. 完成使用

 implementation 'com.github.XXX:XXX:1.0'