iOS底层探究-03：alloc & init & new 源码

在分析 alloc 源码之前，先看一下3个 变量、指针、内存地址 的区别：

分别输出3个对象的 内容、指针地址、对象地址，下图是打印结果

通过打印可以看出，3个对象指向的是同一个内存空间，所以其内容 和 指针地址是相同的，但是对象的内存地址是不同的

• %p -> p1：是指向内存地址的指针
• %p -> &p1：是内存地址

这就是本文需要探索的内容，alloc做了什么？init做了什么？

准备工作

• 下载 objc4-781 源码
• 编译源码，可参考 iOS底层探究-02：objc4-781源码编译&调试

alloc 源码探究

大致流程如下：

• 【第一步】首先根据main函数中的LCPerson类的alloc方法进入alloc方法的源码（即源码分析开始）

+ (id)alloc {
    return _objc_rootAlloc(self);
}

• 【第二步】跳转至_objc_rootAlloc的源码

id
_objc_rootAlloc(Class cls)
{
    return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}

• 【第三步】跳转至callAlloc的源码

static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false)
{
#if __OBJC2__
    if (slowpath(checkNil && !cls)) return nil;
    if (fastpath(!cls->ISA()->hasCustomAWZ())) {
        return _objc_rootAllocWithZone(cls, nil);
    }
#endif

    // No shortcuts available.
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

⚠️注意：当我们无法确定实现具体会走哪步时，可以借助断点调试，判断会走哪部分逻辑。这里是执行到_objc_rootAllocWithZone

• 【第四步】跳转至_objc_rootAllocWithZone的源码

id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused)
{
    // allocWithZone under __OBJC2__ ignores the zone parameter
    return _class_createInstanceFromZone(cls, 0, nil,
                                         OBJECT_CONSTRUCT_CALL_BADALLOC);
}

• 【第五步】跳转至_class_createInstanceFromZone的源码，这部分是alloc源码的核心操作，该方法的实现主要分为三部分：
  大致流程如下：
  

  
  • cls -> instanceSize：计算需要开辟的内存空间大小
  • calloc：申请内存，返回地址指针
  • obj -> initInstanceIsa：将 类 与 isa 关联

static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
                              int construct_flags = OBJECT_CONSTRUCT_NONE,
                              bool cxxConstruct = true,
                              size_t *outAllocatedSize = nil)
{
    ASSERT(cls->isRealized());

    // Read class's info bits all at once for performance
    bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
    bool hasCxxDtor = cls->hasCxxDtor();
    bool fast = cls->canAllocNonpointer();
    size_t size;

    size = cls->instanceSize(extraBytes);
    if (outAllocatedSize) *outAllocatedSize = size;

    id obj;
    if (zone) {
        obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
    } else {
        obj = (id)calloc(1, size);
    }
    if (slowpath(!obj)) {
        if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
            return _objc_callBadAllocHandler(cls);
        }
        return nil;
    }

    if (!zone && fast) {
        obj->initInstanceIsa(cls, hasCxxDtor);
    } else {
        // Use raw pointer isa on the assumption that they might be
        // doing something weird with the zone or RR.
        obj->initIsa(cls);
    }

    if (fastpath(!hasCxxCtor)) {
        return obj;
    }

    construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
    return object_cxxConstructFromClass(obj, cls, construct_flags);
}

cls -> instanceSize：计算所需内存大小

• 跳转至instanceSize的源码

size_t instanceSize(size_t extraBytes) const {
        if (fastpath(cache.hasFastInstanceSize(extraBytes))) {
            return cache.fastInstanceSize(extraBytes);
        }

        size_t size = alignedInstanceSize() + extraBytes;
        // CF requires all objects be at least 16 bytes.
        if (size < 16) size = 16;
        return size;
    }

通过断点调试，会执行到cache.fastInstanceSize方法，计算内存大小

• 跳转至fastInstanceSize的源码，通过断点调试，会执行到align16

size_t fastInstanceSize(size_t extra) const
    {
        ASSERT(hasFastInstanceSize(extra));

        if (__builtin_constant_p(extra) && extra == 0) {
            return _flags & FAST_CACHE_ALLOC_MASK16;
        } else {
            size_t size = _flags & FAST_CACHE_ALLOC_MASK;
            // remove the FAST_CACHE_ALLOC_DELTA16 that was added
            // by setFastInstanceSize
            return align16(size + extra - FAST_CACHE_ALLOC_DELTA16);
        }
    }

• 跳转至align16的源码，这个方法是16字节对齐算法

static inline size_t align16(size_t x) {
    return (x + size_t(15)) & ~size_t(15);
}

内存字节对齐原则

主要有以下三点

• 数据成员对齐规则：struct 或者 union 的数据成员，第一个数据成员放在offset为0的地方，以后每个数据成员存储的起始位置要从该成员大小或者成员的子成员大小（只要该成员有子成员，比如数据、结构体等）的整数倍开始（例如int在32位机中是4字节，则要从4的整数倍地址开始存储）
• 数据成员为结构体：如果一个结构里有某些结构体成员，则结构体成员要从其内部最大元素大小的整数倍地址开始存储（例如：struct a里面存有struct b，b里面有char、int、double等元素，则b应该从8的整数倍开始存储）
• 结构体的整体对齐规则：结构体的总大小，即sizeof的结果，必须是其内部做大成员的整数倍，不足的要补齐

为什么需要16字节对齐

需要字节对齐的原因，有以下几点：

• 通常内存是由一个个字节组成的，cpu在存取数据时，并不是以字节为单位存储，而是以块为单位存取，块的大小为内存存取力度。频繁存取字节未对齐的数据，会极大降低cpu的性能，所以可以通过减少存取次数来降低cpu的开销
• 16字节对齐，是由于在一个对象中，第一个属性isa占8字节，当然一个对象肯定还有其他属性，当无属性时，会预留8字节，即16字节对齐，如果不预留，相当于这个对象的isa和其他对象的isa紧挨着，容易造成访问混乱
• 16字节对齐后，可以加快CPU读取速度，同时使访问更安全，不会产生访问混乱的情况

字节对齐-总结

• 在字节对齐算法中，对齐的主要是对象，而对象的本质则是一个 struct objc_object的结构体，
• 结构体在内存中是连续存放的，所以可以利用这点对结构体进行强转。
• 苹果早期是8字节对齐，现在是16字节对齐。

calloc：申请内存，返回地址指针

通过instanceSize计算的内存大小，向内存中申请 大小 为size 的内存，并赋值给obj，因此 obj是指向内存地址的指针

obj = (id)calloc(1, size);

obj -> initInstanceIsa：类与isa关联

经过calloc，内存已经申请好了，类也已经传入进来了，那么接下来就需要将 类 与 地址指针 即 isa指针进行关联

init 源码探索

alloc源码探索完了，接下来探索init源码，通过源码可知，inti的源码实现有以下两种

类方法 init

• 通过代码进行探索实例方法 init

LCPerson *p1 = [[LCPerson alloc] init];

• 通过main中的init跳转至init的源码

- (id)init {
    return _objc_rootInit(self);
}

• 跳转至_objc_rootInit的源码

id
_objc_rootInit(id obj)
{
    // In practice, it will be hard to rely on this function.
    // Many classes do not properly chain -init calls.
    return obj;
}

有此可见，返回的是传入的self本身。

new 源码探索

一般在开发中，初始化除了init，还可以使用new，两者本质上并没有什么区别，以下是objc中new的源码实现，通过源码可以得知，new函数中直接调用了callAlloc函数（即alloc中分析的函数），且调用了init函数，所以可以得出new 其实就等价于 [alloc init]的结论

+ (id)new {
    return [callAlloc(self, false/*checkNil*/) init];
}

⚠️注意：但是一般开发中并不建议使用new，主要是因为有时会重写init方法做一些自定义的操作，例如 initWithXXX，会在这个方法中调用[super init]，用new初始化可能会无法走到自定义的initWithXXX部分。