Swift--001：Swift编译 & SIL分析

Swift与OC编译区别

swift与oc编译区别

• Swfit使用前端编译器swiftc，降级编译成IR，再通过后端编译器LLVM生成.o可执行文件。
• OC使用前端编译器Clang编译出IR，再通过后端编译器LLVM生成.o可执行文件。

Swift编译流程

swift编译流程 SwiftCode->通过词法分析、语法分析(-dump-parse)->生成AST抽象语法树(-dump-ast)->通过SILGen生成未优化代码量巨大的RawSIL文件(-emit-silgen)->再拿到优化后更简洁的Canonical SIL(-emit-sil)->通过IRGen生成IR(-emit-ir)->最终生成二进制代码

swiftc命令

使用swiftc -h，查看所有命令

swiftc -h

SIL分析

创建项目，在main.swift写入以下代码：

import Foundation

class LGTeacher{
    
    var age: Int=18;
    var name: String="Zang";
}

var t=LGTeacher();

• 查看AST语法树：swiftc -dump-ast main.swift AST语法树 语法树可以干很多事情，比如针对当前代码校验，这里会涉及到大量编译器知识。

• 查看优化后SIL代码：swiftc -emit-sil main.swift

LGTeacher分析：

//LGTeacher
class LGTeacher {
  //age和name两个存储属性
  @_hasStorage @_hasInitialValue var age: Int { get set }
  @_hasStorage @_hasInitialValue var name: String { get set }
  //@objc标记的deinit方法
  @objc deinit
  //init方法
  init()
}

@_hasStorage @_hasInitialValue var t: LGTeacher { get set }

// t
//这个复杂的字符串就是当前的t，只是经过了swift混写之后的
//可以使用xcrun命令进行还原
sil_global hidden @$s4main1tAA9LGTeacherCvp : $LGTeacher

//通过xcrun命令还原混写后的字符串：
xcrun swift-demangle s4main1tAA9LGTeacherCvp
//输出结果：
$s4main1tAA9LGTeacherCvp ---> main.t : main.LGTeacher

main函数分析：

// main
//@main就是应用程序的入口，
//@convention(c)表示c函数
//函数里有两个参数，一个Int32位整形参数，一个UnsafeMutablePointer指针参数
//函数有一个Int32位整形的返回值
sil @main : $@convention(c) (Int32, UnsafeMutablePointer<Optional<UnsafeMutablePointer<Int8>>>) -> Int32 {
bb0(%0 : $Int32, %1 : $UnsafeMutablePointer<Optional<UnsafeMutablePointer<Int8>>>):
  //%0、%1...表示寄存器，与register read不是一个东西，这里的只是虚拟寄存器
  //一旦赋值就不会再改变，类似编程语言中的开发常量
  //alloc_global：分配全局变量，其实就是上面的t
  //看这里的@$s4main1tAA9LGTeacherCvp，和上面的t完全一致  
  alloc_global @$s4main1tAA9LGTeacherCvp          // id: %2
  //global_addr：将全局变量地址赋值给%3
  %3 = global_addr @$s4main1tAA9LGTeacherCvp : $*LGTeacher // user: %7
  //将LGTeacher.Type，也就是元类型赋值给%4
  %4 = metatype $@thick LGTeacher.Type            // user: %6
  // function_ref LGTeacher.__allocating_init()
  // 拿到__allocating_init的方法地址赋值给%5
  %5 = function_ref @$s4main9LGTeacherCACycfC : $@convention(method) (@thick LGTeacher.Type) -> @owned LGTeacher // user: %6
  // 通过apply调用%5也就是__allocating_init函数，并传入参数%4，将返回值赋值给%6
  %6 = apply %5(%4) : $@convention(method) (@thick LGTeacher.Type) -> @owned LGTeacher // user: %7
  //将返回的实例结果%6存储到%3
  store %6 to %3 : $*LGTeacher                    // id: %7
  //构建0，返回状态码
  %8 = integer_literal $Builtin.Int32, 0          // user: %9
  %9 = struct $Int32 (%8 : $Builtin.Int32)        // user: %10
  return %9 : $Int32                              // id: %10
} // end sil function 'main'

总结：

• @main这⾥标识我们当前 main.swift 的⼊⼝函数，SIL 中的标识符名称以 @ 作为前缀
• %0，%1...在 SIL 也叫做寄存器，这⾥我们可以理解为我们⽇常开发中的常量，⼀旦赋值之后就不可 以再修改，如果 SIL 中还要继续使⽤，那么就不断的累加数字。同时这⾥所说的寄存器是虚拟的，最 终运⾏到我们的机器上，会使⽤真的寄存器。
• alloc_gobal创建⼀个全局变量
• global_addr拿到全局变量的地址，赋值给 %3
• metatype拿到 LGTeacher 的 Metadata 赋值给 %4
• 将__allocating_init的函数地址赋值给 %5
• apply 调⽤__allocating_init, 并把返回值给 %6
• 将%6的值存储到%3（也就是我们刚刚创建的全局变量的地址）
• 构建Int, 并return

LGTeacher.__allocating_init分析：

// LGTeacher.__allocating_init()
sil hidden [exact_self_class] @$s4main9LGTeacherCACycfC : $@convention(method) (@thick LGTeacher.Type) -> @owned LGTeacher {
  // %0 "$metatype"
  bb0(%0 : $@thick LGTeacher.Type):
  //alloc_ref：在堆上分配内存空间
  %1 = alloc_ref $LGTeacher                       // user: %3
  // function_ref LGTeacher.init()
  //调用init方法，初始化当前变量
  %2 = function_ref @$s4main9LGTeacherCACycfc : $@convention(method) (@owned LGTeacher) -> @owned LGTeacher // user: %3
  //将实例变量返回
  %3 = apply %2(%1) : $@convention(method) (@owned LGTeacher) -> @owned LGTeacher // user: %4
  return %3 : $LGTeacher                          // id: %4
} // end sil function '$s4main9LGTeacherCACycfC'

总结：

• alloc_ref创建⼀个LGTeacher的实例对象，当前实例对象的默认引⽤计数为1
• 调⽤init⽅法

• 详细对SIL的内容进⾏探索，可以参考 这个视频
• 更多SIL语法信息，可以查看 这个网站

• 查看LLVM IR代码：swiftc -emit-ir main.swift IR代码

• 查看汇编代码：swiftc -emit-assembly main.swift 汇编代码