iOS alloc&init原理探索

2021-02-07  本文已影响0人  辉辉岁月

首先

    LGPerson *p1 = [LGPerson alloc];
    LGPerson *p2 = [p1 init];
    LGPerson *p3 = [p1 init];
   
    LGNSLog(@"%@ - %p - %p",p1,p1,&p1);
    LGNSLog(@"%@ - %p - %p",p2,p2,&p2);
    LGNSLog(@"%@ - %p - %p",p3,p3,&p3);

<LGPerson: 0x60000307dcc0> - 0x60000307dcc0 - 0x7ffee6ff2068
<LGPerson: 0x60000307dcc0> - 0x60000307dcc0 - 0x7ffee6ff2060
<LGPerson: 0x60000307dcc0> - 0x60000307dcc0 - 0x7ffee6ff2058

为什么

原因

Class cls1 = objc_getClass(p1);
NSLog(@"%p" , cls1);

0x1022147c8

那么到底alloc＆init的原理是什么呢？

准备工作

alloc源码探索

流程

源碼搭配斷點調適查看 alloc:

+ (id)alloc {
    return _objc_rootAlloc(self);
}

进入_objc_rootAlloc

id _objc_rootAlloc(Class cls) {
    return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}

进入callAlloc

static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false) {
#if __OBJC2__
    // checkNil 为false，!cls 也为false ，不会返回nil
    if (slowpath(checkNil && !cls)) return nil;
    // 是否有自定义的 +allocWithZone 实现
    if (fastpath(!cls->ISA()->hasCustomAWZ())) {
        return _objc_rootAllocWithZone(cls, nil);
    }
#endif
    // No shortcuts available.
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

怎么知道是走到_objc_rootAllocWithZone 的呢？

//x很可能为1，程式走if括弧內的實現
#define fastpath(x) (__builtin_expect(bool(x), 1)) 
//x很可能为0，程式走else括弧內的實現
#define slowpath(x) (__builtin_expect(bool(x), 0)) 

static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false)// alloc 源码 第三步
{
#if __OBJC2__ //有可用的编译器优化
    /*
     参考链接：(https://www.jianshu.com/p/2684613a300f)
     */
    
    // checkNil 为false，!cls 也为false ，所以slowpath 为 false，假值判断不会走到if里面，即不会返回nil
    //fastpath(x)表示x很可能不為0，希望編譯器進行優化；slowpath(x)表示x很可能為0，希望編譯器進行優化-這裡表示cls大概率是有值的，編譯器可以不用每次都讀取return nil指令
    if (slowpath(checkNil && !cls)) return nil;
    
    //判断一个类是否有自定义的 +allocWithZone 实现，没有则走到if里面的实现
    if (fastpath(!cls->ISA()->hasCustomAWZ())) {
        return _objc_rootAllocWithZone(cls, nil);
    }
#endif

    // No shortcuts available. // 没有可用的编译器优化
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

跳转至_objc_rootAllocWithZone 的源码实现

跳转至_class_createInstanceFromZone 的源码实现，這部分是alloc源碼的核心操作，该方法的实现主要分为三个部分

static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
                              int construct_flags = OBJECT_CONSTRUCT_NONE,
                              bool cxxConstruct = true,
                              size_t *outAllocatedSize = nil)// alloc 源码 第五步
{
    ASSERT(cls->isRealized()); //检查是否已经实现

    // Read class's info bits all at once for performance
    //一次性读取类的位信息以提高性能
    bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
    bool hasCxxDtor = cls->hasCxxDtor();
    bool fast = cls->canAllocNonpointer();
    size_t size;

    //计算需要开辟的内存大小，传入的extraBytes 为 0
    size = cls->instanceSize(extraBytes);
    if (outAllocatedSize) *outAllocatedSize = size;

    id obj;
    if (zone) {
        obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
    } else {
        //申请内存
        obj = (id)calloc(1, size);
    }
    if (slowpath(!obj)) {
        if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
            return _objc_callBadAllocHandler(cls);
        }
        return nil;
    }

    if (!zone && fast) {
        //将 cls类 与 obj指针（即isa） 关联
        obj->initInstanceIsa(cls, hasCxxDtor);
    } else {
        // Use raw pointer isa on the assumption that they might be
        // doing something weird with the zone or RR.
        obj->initIsa(cls);
    }

    if (fastpath(!hasCxxCtor)) {
        return obj;
    }
    construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
    return object_cxxConstructFromClass(obj, cls, construct_flags);
}

alloc核心操作

cls->instanceSize:计算所需内存大小

流程

跳转至instanceSize 的源码实现

size_t instanceSize(size_t extraBytes) const {
    //编译器快速计算内存大小
    if (fastpath(cache.hasFastInstanceSize(extraBytes))) {
        return cache.fastInstanceSize(extraBytes);
    }

    // 计算类中所有属性的大小 + 额外的字节数0
    size_t size = alignedInstanceSize() + extraBytes;
    // CF requires all objects be at least 16 bytes.
    //如果size 小于 16，最小取16
    if (size < 16) size = 16;
    return size;
}

跳转至fastInstanceSize 的源码实现，通过断点调试，來到align16

size_t fastInstanceSize(size_t extra) const
{
    ASSERT(hasFastInstanceSize(extra));

    //Gcc的内建函数 __builtin_constant_p 用于判断一个值是否为编译时常数，如果参数EXP 的值是常数，函数返回 1，否则返回 0
    if (__builtin_constant_p(extra) && extra == 0) {
        return _flags & FAST_CACHE_ALLOC_MASK16;
    } else {
        size_t size = _flags & FAST_CACHE_ALLOC_MASK;
        // remove the FAST_CACHE_ALLOC_DELTA16 that was added
        // by setFastInstanceSize
        //删除由setFastInstanceSize添加的FAST_CACHE_ALLOC_DELTA16 8个字节
        return align16(size + extra - FAST_CACHE_ALLOC_DELTA16);
    }
}

跳转到align16的源码实现，以下是16字节对齐算法

//16字節對齊算法
static inline size_t align16(size_t x) {
    return (x + size_t(15)) & ~size_t(15);
}

想知道什么是16字节对齐算法，请先参考

内存对齐原理

为什么要16字节对齐

16字节对齐算法

//16字節對齊算法
static inline size_t align16(size_t x) {
    return (x + size_t(15)) & ~size_t(15);
}

calloc:申請內存，返回地址指針

obj = (id)calloc(1, size);

obj->initInstanceIsa：类与isa关联

8 经过calloc可知，內存已经申请好了，类也已经传入进来了，接下來就需要将类与地址指针即isa指针进行关联，其关联的流程圖如下所示


类与isa关联

initInstanceIsa流程

总结

通過对alloc源码的分析，可以得知alloc的主要目的就是开辟内存，而且开辟的内存需要使用16字节对齐算法，现在开辟的内存的大小基本上都是16的整數倍
开辟内存的核心步骤有3步：计算 -- 申请 -- 关联

init源码探索

类方法init

+ (id)init {
    return (id)self;
}

实例方法init

通過以下代码进行探索实例方法init

LGPerson *objc = [[LGPerson alloc] init];

通過main中的init跳转至init的源码实现

- (id)init {
    return _objc_rootInit(self);
}

跳转至_objc_rootInit的源码实现

id
_objc_rootInit(id obj)
{
    // In practice, it will be hard to rely on this function.
    // Many classes do not properly chain -init calls.
    return obj;
}

有上述代码可以，返回的是传入的self本身。

new 源碼探索

一般在开发中，初始化除了init，还可以使用new，两者本质上并沒有什么区別，以下是objc中new的源码实现，通過源码可以得知，new函數中直接调用了callAlloc函數（即alloc中分析的函數），且调用了init函數，所以可以得出new 其实就等价于 [alloc init]的结论

上一篇下一篇

猜你喜欢

热点阅读