6、[VBA入门到放弃笔记]if...end if结构

• VBA中常用到的判断就是使用if...end if,掌握了For循环和IF结构就能完成很多事情。
• 1.[ if....end if ] 结构

if 条件1...条件2.... then '写if结构时，写完if就写end if，这样不会漏
        代码
end if

练习1：实现数据筛选。按班级筛选所有数据（高级筛选）

筛选数据

Sub 筛选数据()
    Dim i As Integer, k As Integer
    Dim Class As String
    k = 4 '初始值K=4
    Class = Range("G2").Value '提取的班级
    Range("G5:I100").ClearContents '每次提取不同班级时清除原来的数据，清空一个足够大的单元格范围的内容即可
    For i = 2 To 13
        If Cells(i, 1) = Class Then '如果A列中的班级符合条件，那么
            k = k + 1 '符合条件就计算数据条数,第5行开始
            Cells(k, "G") = Cells(i, 1) '提取班级数据到G列
            Cells(k, "H") = Cells(i, 2) '姓名到H列
            Cells(k, "I") = Cells(i, 3) '总分到I列
      End If
   Next
End Sub

Paste_Image.png

---

• 2.1 [ if.....else....end if ]结构

if 条件 then
    代码
else
    代码
end if

• 练习2：身份证第17位数，如果为奇数，则是男性，否则是女性。

Sub 身份证号码判断男女()
    Dim x As String
    x = "440182199010010617" '身份证号码
    If Mid(x, 17, 1) Mod 2 = 1 Then 'mid函数提取身份证第17位数字,mod求余数，奇数和2的余数为1，偶数和2的余数为0
        MsgBox "是个抠脚大叔"
    Else
        MsgBox "是个温柔小妹"
    End If
End Sub

---

2.2 [ if....elseif.....else....end if ]结构

练习3：判断成绩等级。

Sub 评优() 
    Dim i As Integer
    For i = 2 To 10 
        If Cells(i, 2) >= 90 Then'成绩>=90
            Cells(i, 3) = "优秀"
        ElseIf Cells(i, 2) >= 80 And Cells(i, 2) < 90 Then'成绩80(含80)以上90以下
            Cells(i, 3) = "良"
        ElseIf Cells(i, 2) >= 70 And Cells(i, 2) < 80 Then
            Cells(i, 3) = "中"
        ElseIf Cells(i, 2) >= 60 And Cells(i, 2) < 70 Then
            Cells(i, 3) = "及格"
        Else
            Cells(i, 3) = "不及格"
        End If
    Next
End Sub

• if一旦判断成立，则会退出判断，循环开始下一次成绩判断。看GIF图黄色的代码跳转。

• 上面代码条件可以改写为(注意判断条件的顺序),假如将Cells(i, 2) >= 80和Cells(i, 2) >= 90两句代码的条件和评价结果调换，则会发生错误.如韩信的成绩是91,第一次判断91>80，条件成立，则韩信评为‘良’，就不会执行第二句的判断代码Cells(i, 2) >= 90。可自行调换代码测试......

Sub 评优1()
    Dim i As Integer
    For i = 2 To 10
        If Cells(i, 2) >= 90 Then
        Cells(i, 3) = "优秀"
    ElseIf Cells(i, 2) >= 80 Then
        Cells(i, 3) = "良"
    ElseIf Cells(i, 2) >= 70 Then
        Cells(i, 3) = "中"
    ElseIf Cells(i, 2) >= 60 Then
        Cells(i, 3) = "及格"
    Else
        Cells(i, 3) = "不及格"
    End If
Next
End Sub

• 不好的代码

Sub 评优1()
    Dim i As Integer
    For i = 2 To 10
        If Cells(i, 2) >= 80 Then
        Cells(i, 3) = "良"
    ElseIf Cells(i, 2) >= 90 Then
        Cells(i, 3) = "优秀"
    ElseIf Cells(i, 2) >= 70 Then
        Cells(i, 3) = "中"
    ElseIf Cells(i, 2) >= 60 Then
        Cells(i, 3) = "及格"
    Else
        Cells(i, 3) = "不及格"
    End If
Next
End Sub

---

• 【补充】有时候if语句可以写成一条

If 1 > 2 Then a = a + 1 Else b = b + 1
If 1 > 2 Then MsgBox False

练习4：按已知的部门汇总.

Paste_Image.png

Sub 求和()
    Dim i As Integer
    Dim S As Integer
    For i = 2 To 5 '遍历D列的部门,先在A列查找所有的部门1,然后是所有的部门2......
        For j = 2 To 13 '遍历A列的部门(数据源区域)
            If Cells(j, 1) = Cells(i, "D") Then '如果A列的部门等于D列的部门，那么
                S = S + Cells(j, 2) '同部门累加
            End If
        Next
        Cells(i, "E") = S '遍历完所有部门后输出累加的销售总额到E列
        S = 0 '累加下一个部门，S要清零
    Next
End Sub

结果

---