动态水指定方向流向

原始借鉴网址 https://www.shadertoy.com/view/Ms2SD1

对原始代码改动，去掉天空背景，去掉镜头旋转效果；

增加水按指定方向流淌效果；

const int NUM_STEPS = 20;

const float PI = 3.141592;

const float EPSILON = 1e-3;

// add by sunny begin

float u_speedTime = 0.3; // glsl场景渲染速度系数 0.1~1.0

float u_seaSpeedTime = 0.8; // 海面海浪速度系数 0.1~1.0

float u_choppy = 0.8; // 海浪振幅系数 0.1~100.0

float u_oriTime = 1.0; // 海浪方向系数 0.1~10.0

// add by sunny end

// sea

const int ITER_GEOMETRY = 2;

const int ITER_FRAGMENT = 4;

const float SEA_HEIGHT = 0.6;

const float SEA_CHOPPY = 10.0;

const float SEA_SPEED = 0.8;

const float SEA_FREQ = 0.16;

const vec3 SEA_BASE = vec3(0.0,0.09,0.18);

const vec3 SEA_WATER_COLOR = vec3(0.8,0.9,0.6)*0.6;

#define SEA_TIME (1.0 + iTime * SEA_SPEED)

// 海浪倍频矩阵， GLSL 是列矩阵存储（标志每单位面积内浪花多少）

const mat2 octave_m = mat2(1.6,1.2,-1.2,1.6);

// math欧拉角转四元数, 给定一个欧拉角,可以返回一个表示旋转的四元数对象(旋转矩阵)

mat3 fromEuler(vec3 ang) {

vec2 a1 = vec2(sin(ang.x),cos(ang.x));

    vec2 a2 = vec2(sin(ang.y),cos(ang.y));

    vec2 a3 = vec2(sin(ang.z),cos(ang.z));

    mat3 m;

    m[0] = vec3(a1.y*a3.y+a1.x*a2.x*a3.x,a1.y*a2.x*a3.x+a3.y*a1.x,-a2.y*a3.x);

m[1] = vec3(-a2.y*a1.x,a1.y*a2.y,a2.x);

m[2] = vec3(a3.y*a1.x*a2.x+a1.y*a3.x,a1.x*a3.x-a1.y*a3.y*a2.x,a2.y*a3.y);

return m;

}

// 散列表（随机）

float hash( vec2 p ) {

float h = dot(p,vec2(127.1,311.7));

    return fract(sin(h)*43758.5453123);

}

// 距离场噪声

float noise( in vec2 p ) {

    vec2 i = floor( p );

    vec2 f = fract( p );

vec2 u = f*f*(3.0-2.0*f);

    return -1.0+2.0*mix( mix( hash( i + vec2(0.0,0.0) ),

                    hash( i + vec2(1.0,0.0) ), u.x),

                mix( hash( i + vec2(0.0,1.0) ),

                    hash( i + vec2(1.0,1.0) ), u.x), u.y);

}

// lighting 环境光（迷漫、无方向）

float diffuse(vec3 n,vec3 l,float p) {

    return pow(dot(n,l) * 0.4 + 0.6,p);

}

// 点光源光（有方向的镜面反射光）

float specular(vec3 n,vec3 l,vec3 e,float s) {   

    float nrm = (s + 8.0) / (PI * 8.0);

    return pow(max(dot(reflect(e,n),l),0.0),s) * nrm;

}

// sky 获取天空颜色

vec3 getSkyColor(vec3 e) {

    e.y = (max(e.y,0.0)*0.8+0.2)*0.8;

    return vec3(pow(1.0-e.y,2.0), 1.0-e.y, 0.6+(1.0-e.y)*0.4) * 1.1;

}

// sea 海面海浪

float sea_octave(vec2 uv, float choppy) {

    uv += noise(uv);       

    vec2 wv = 1.0-abs(sin(uv));

    vec2 swv = abs(cos(uv));   

    wv = mix(wv,swv,wv);

    return pow(1.0-pow(wv.x * wv.y,0.65),choppy);

}

//

float map(vec3 p) {

    float freq = SEA_FREQ;

    float amp = SEA_HEIGHT;

    float choppy = SEA_CHOPPY * u_choppy;

    vec2 uv = p.xz; uv.x *= 0.75;

    float sea_time = 1.0 + iTime * u_seaSpeedTime;

    float d, h = 0.0;   

    for(int i = 0; i < ITER_GEOMETRY; i++) {       

    d = sea_octave((uv+sea_time)*freq,choppy);

    //d += sea_octave((uv-sea_time)*freq,choppy);

        h += d * amp;       

    uv *= octave_m; freq *= 1.9; amp *= 0.22;

        choppy = mix(choppy,1.0,0.2);

    }

    return p.y - h;

}

// 地图细节

float map_detailed(vec3 p) {

    float freq = SEA_FREQ;

    float amp = SEA_HEIGHT;

    float choppy = SEA_CHOPPY * u_choppy;

    vec2 uv = p.xz; uv.x *= 0.75;

    float d, h = 0.0; 

    float sea_time = 1.0 + iTime * u_seaSpeedTime;

    for(int i = 0; i < ITER_FRAGMENT; i++) {       

    d = sea_octave((uv+sea_time)*freq,choppy);

    //d += sea_octave((uv-sea_time)*freq,choppy);

        h += d * amp;       

    uv *= octave_m; freq *= 1.9; amp *= 0.22;

        choppy = mix(choppy,1.0,0.2);

    }

    return p.y - h;

}

// 获取海面颜色

vec3 getSeaColor(vec3 p, vec3 n, vec3 l, vec3 eye, vec3 dist) {

    // // 聚光灯、主光源

    float fresnel = clamp(1.0 - dot(n,-eye), 0.0, 1.0);

    fresnel = pow(fresnel,3.0) * 0.5;

    vec3 reflected = getSkyColor(reflect(eye,n));  // 反射光 

    vec3 refracted = SEA_BASE + diffuse(n,l,80.0) * SEA_WATER_COLOR * 0.12; // 折射光

    vec3 color = mix(refracted,reflected,fresnel);

    float atten = max(1.0 - dot(dist,dist) * 0.001, 0.0);

    color += SEA_WATER_COLOR * (p.y - SEA_HEIGHT) * 0.18 * atten;

    color += vec3(specular(n,l,eye,60.0));

    return color;

}

// tracing 获取法向量

vec3 getNormal(vec3 p, float eps) {

    vec3 n;

    n.y = map_detailed(p);   

    n.x = map_detailed(vec3(p.x+eps,p.y,p.z)) - n.y;

    n.z = map_detailed(vec3(p.x,p.y,p.z+eps)) - n.y;

    n.y = eps;

    return normalize(n);

}

// 海浪高度图跟踪

float heightMapTracing(vec3 ori, vec3 dir, out vec3 p) { 

    float tm = 0.0;

    float tx = 1000.0;   

    float hx = map(ori + dir * tx);

    if(hx > 0.0) {

        p = ori + dir * tx;

        return tx; 

    }

    float hm = map(ori + dir * tm);   

    float tmid = 0.0;

    for(int i = 0; i < NUM_STEPS; i++) {

        tmid = mix(tm,tx, hm/(hm-hx));                 

        p = ori + dir * tmid;                 

    float hmid = map(p);

if(hmid < 0.0) {

        tx = tmid;

            hx = hmid;

        } else {

            tm = tmid;

            hm = hmid;

        }

    }

    return tmid;

}

// 获取像素-等同于cesium中czm_getMaterial函数

vec3 getPixel(in vec2 coord, float time) {   

    vec2 uv = coord / iResolution.xy;

    uv = uv * 2.0 - 1.0;

    uv.x *= iResolution.x / iResolution.y;   

    // ray

    vec3 angForEuler = vec3(0.0,0.7,.0); // 欧拉参数，用于 

    vec3 ori = vec3(0.0,0.7,time*u_oriTime);

    vec3 dir = normalize(vec3(uv.xy,-2.0));

    dir.z += length(uv) * 0.14;

    dir = normalize(dir) * fromEuler(angForEuler);

    // tracing

    vec3 p;

    heightMapTracing(ori,dir,p);

    vec3 dist = p - ori;

    vec3 n = getNormal(p, dot(dist,dist) * EPSILON);

    vec3 light = normalize(vec3(0.0,1.0,0.8));

    // color

    return mix(

        getSkyColor(dir),

        getSeaColor(p,n,light,dir,dist),

    pow(smoothstep(0.0,-0.02,dir.y),0.2));

}

// main

void mainImage( out vec4 fragColor, in vec2 fragCoord ) {

    float time = iTime * u_speedTime ;

    vec3 color = getPixel(fragCoord, time);

    // post

fragColor = vec4(pow(color,vec3(0.65)), 1.0);

}