20170809 sed文本处理工具

一、sed 工具简介

• sed Stream EDitor, 行编辑器

• 工具特性：sed是一种流编辑器，每次处理一行文本内容。

• 工作过程：将当前行储存至内存空间中，称作“模式空间”(pattern space)。在模式空间中对行进行编辑，将处理结果输出至屏幕。一般情况下，清空模式空间内容，然后读入下一行执行下一个循环，如此循环直至文本文件行尾。

• 功能：编辑一个或多个文件，简化对文件的反复操作，编写转换程序等

二、sed 工具基本用法

1. 语法：sed [option]... 'script' inputfile...

2. 选项：

-n         //不输出模式空间内容到屏幕，即不自动打印
-e         //多点编辑
-f /PATH/SCRIPT_FILE     //从指定文件中读取编辑脚本
-r         //支持使用扩展正则表达式
-i         //文件原处编辑
-i.bak     //备份文件（后缀 .bak）并原处编辑

3. 'script' 描述对文本的地址定界和编辑命令

• 地址定界

  • （1）不给地址：代表全文处理
  • （2）单地址：
    #：指定第#行
    /pattern/：匹配模式描述的每一行
  • （3）地址范围
    m,n：从第m行到第n行
    m,+n：从第m行到第(m+n)行
    /pat1/,/pat2/：从匹配pat1的行到匹配pat2的行
    m,/pat1/：从第m行到匹配pat1的行
  • （4）步进 ~
    1~2：从1开始，每次步进2，即1，3，5，7···奇数列
    2~2：从2开始，每次步进2，即2，4，6，8···偶数列

• 编辑命令

d                     //删除模式空间匹配的行，并立即启用下一轮循环
p                     //打印当前模式空间内容，追加到默认输出之后
a[\]text              //在指定行后面追加文本，支持使用\n实现多行追加
i[\]text              //在行前面插入文本
c[\]text              //替换行为单行或多行文本
w /path/somefile      //保存模式匹配的行至指定文件
r /path/somefile      //读取指定文件的文本至模式空间中匹配到的行后
=                     //为模式空间中的行打印行号
!                     //模式空间中匹配行取反处理

• 查找替换 s/regexp/replacement/修饰符

  • 替代内容 replacement：
    可以使用&符号指代匹配regexp表达式的内容，可也以出现\1, \2等正则表达式后项引用

  • 修饰符：
    g：全局替换
    p：显示替换成功的行
    w /path/somefile：将替换成功的行保存至文件中

  • 支持s@@@，s###等格式代替/号，当查找和替换内容描述中有/符号为避免使用过多转义字符时使用

• 实验：

sed '2p' /etc/passwd                       //打印/etc/passwd文件全部行，第2行重复打印一次
sed -n '2p' /etc/passwd                    //只打印/etc/passwd文件第2行     
sed -n '1,4p' /etc/passwd                  //打印/etc/passwd文件第1-4行
sed -n '/root/p' /etc/passwd               //打印/etc/passwd文件包含root的行
sed -n '2,/root/p' /etc/passwd从2行开始     //打印/etc/passwd文件第2行到包含root的行
sed -n '/^$/=' /etc/bashrc'                //显示/etc/bash_rc文件空行行号
sed -n -e '/^$/p' -e '/^$/=' /etc/bashrc   //打印/etc/bashrc文件空行并显示空行行号
sed '/root/a\superman' /etc/passwd         //在/etc/passwd文件root行后添加superman行
sed '/root/i\superman' /etc/passwd         //在/etc/passwd文件root行前添加superman行
sed '/root/c\superman' /etc/passwd         //在/etc/passwd文件root行替换为superman行
sed '/^$/d' /etc/bashrc                    //删除/etc/bashrc文件空行
sed '1,10d' /etc/bashrc                    //删除/etc/bashrc文件第1-10行
sed 's/ftp/vsftpd/g' /etc/passwd           //将/etc/passwd文件中的ftp全部替换为vsftpd     
sed -n 's/root/&superman/pg' /etc/passwd    //将/etc/passwd文件中的root后添加superman并显示修改的行
sed -n 's/root/superman&/pg' /etc/passwd    //将/etc/passwd文件中的root前添加superman并显示修改的行

三、sed 工具高级用法

• 保持空间(hold space)：一段内存空间，可以从模式空间读数据也可向模式空间写数据，为sed工具提供了更加灵活的使用方法。

• 选项：

P     //打印模式空间开端至第一个换行符内容，并追加到默认输出之前
h     //把模式空间中的内容覆盖至保持空间中
H     //把模式空间中的内容追加至保持空间中
g     //从保持空间取出数据覆盖至模式空间
G     //从保持空间取出内容追加至模式空间
x     //把模式空间中的内容与保持空间中的内容进行互换
n     //读取匹配到的行的下一行覆盖至模式空间
N     //读取匹配到的行的下一行追加至模式空间
d     //删除模式空间中的行
D     //如果模式空间包含换行符，则删除模式空间开端至第一个换行符内容，重新启动循环但不会读取新的输入行。
      如果模式空间不包含换行符，则会像发出d命令那样启动正常的新循环

• 实验：

sed -n 'n;p' num          //打印偶数行
sed '1!G;h;$!d' num       //倒序输出行
sed 'N;D' num             //打印最后一行
sed '$!N;$!D' num         //打印最后两行
sed '$!d' num             //打印最后一行
sed 'G' num               //每一行后添加一行空行
sed 'g' num               //将每一行都清空为空行
sed '/^$/d;G' num         //所有空行删除，所有非空行之间添加一行空行
sed 'n;d' num             //打印奇数行
sed -n '1!G;h;$p' num     //倒序输出行