Solidity概述

Solidity 是用于编写智能合约(smart contract)的语言，从语法上和python，javascript类似，相比主流编程语言缺少类似多线程，并发等高级特性。

文件结构

solidity 源文件通常以.sol为后缀，其基本结构如下：

pragma solidity version

import filename
import SymbolName as  SymbolName from filename

contract ContractName {

}

第一行定义了编译solidity文件所使用的编译器版本，例如 ^0.4.21 , 其中 ^ 符号表示向后兼容。import 表示引用其他solidity文件中的符号，其文件路径和linux类似，“.” 表示当前目录， ..表示上级目录。contract定义了合约的主体，包括field，constructor等一系列信息。

Contract

在一个contract内部，可以定义下面几种类型：

• field - contract内部的状态信息，和java中成员变量类似，持久化存储
• function - 和其他编程语言中的函数类似，contract中的基本执行单元
• modifier - solidity 支持自定义修饰符，作用域函数，用于控制函数的访问
• events - 由于区块链的访问都是异步的，函数的调用无法理解返回结果，可以使用event将结果写入log中
• struct - 和c语言中struct 类似，用于自定义类型
• enum - 和其他编程语言类似，用于定义取值范围有限的类型
• constructor - 在合约被创建是调用，用于初始化合约

一个例子

下面是一个例子，包含了一个contract中各类基本元素，初学者可以通过这段代码对solidity有一个初步的感性的认识。

1. 定义了枚举 StateCode，用于定义账户的状态编码 {normal, suspender}.
2. 定义了结构体 State用于表述账户状态信息
3. 定义了三个event，分别用于表示错误，授予金额，以及状态变更
4. 定义了两个Modifier, OnlyManager用于限制仅合约所有者可以调用，NotOverFlow用于防止溢出
5. 定义了三个filed,分别表示合约所有者，用户余额，以及用户状态
6. 定义了一个无参数的构造函数，构造函数中将owner初始化为创建合约的用户地址
7. 定义了两个函数，grant用于授予用户一定的金额，changeState用于改变用户状态

pragma solidity ^0.4.21;

contract WalletManager {
    
    enum StateCode{ 
        normal,suspended
    }

   struct State {
       StateCode code;
       uint changeCount;
   }
   
    event Error(bytes message);
    event Granted(address to, uint amount);
    event StateChanged(address _address, StateCode state);

    modifier OnlyOwner() {
        if (msg.sender != owner) {
            emit Error("Only onwer of the wallet can do");
            return;
         }
        _;
    }
    
    modifier NotOverFlow(address to, uint amount) {
        if (banalces[to] + amount < banalces[to]) {
            emit Error("Overflow");
             return;
        }
        _;
    }
    
    address owner;
    mapping(address => uint) banalces;
    mapping(address => State) states;
    
    constructor() public {
       owner = msg.sender;
    }
    
    function grant(address user, uint amount) public OnlyOwner() NotOverFlow(user, amount){
        banalces[user] += amount;
        emit Granted(user, amount);
    }
    
    function changeState(address _address, StateCode newState) public OnlyOwner() {
        states[_address].code = newState;
        states[_address].changeCount++;
        emit StateChanged(_address,newState);
    }

}

Remix IDE

Remix 是一个基于浏览器的ide, 适用于开发小型的只能合约。可以通过访问remix网站直接使用。也可以按照remix github上的方法搭建离线版本。

remix 基本布局如下：

基本布局

截图中，从左到有分别是，文件列表，代码编辑，控制台，和选项窗口，使用起来非常简单，这里不做过多介绍。