13. Solidity：接收ETH、回调函数、发送ETH

13.1 接受ETH

在智能合约中，对一个函数标记payable关键词，那么这个函数可以接受ETH（合约并不能接收ETH，需要添加回调函数，下节介绍）：

contract Payable {
    function deposit() external payable {}

    function getBalance() external view returns (uint256) {
        return address(this).balance;
    }
}

运行结果：

接收ETH

• deposit函数变红，说明函数可以接受ETH。
• value输入框中输入1，调用deposit方法，向合约中存入1 wei 以太坊；再调用getBalance方法，发现合约余额为1 wei 以太坊。

13.2 回调函数

Solidity支持两种特殊的回调函数，receive()和fallback()，他们主要在两种情况下被使用：

1. 接收ETH
2. 处理合约中不存在的函数调用（代理合约proxy contract）

注意：在solidity 0.6.x版本之前，语法上只有fallback()函数，用来接收ETH时调用以及在被调用函数签名没有匹配到时调用。 0.6版本之后，solidity才将 fallback()函数拆分成receive()和fallback()两个函数。

13.2.1 receive()函数

• receive()只用于处理接收ETH
• 一个合约最多有一个receive()函数，声明方式与一般函数不一样，不需要 function关键字
• receive()函数不能有任何的参数，不能返回任何值
• receive()函数必须包含external和payable关键字
  示例：

contract ReceiveAndFallback {
    event Log(string func, address sender, uint256 value, bytes data);

    receive() external payable {
        emit Log("reveive", msg.sender, msg.value, "");
    }
}

向合约发送ETH：

向合约发送ETH

log：

[
    {
        "from": "0x9EC5FBB6cA79E47c12B485235428f03D24498077",
        "topic": "0xf7f75251dee7d7fc22deac3247729ebe7c86541f35930bf10c2a4207479a3b6c",
        "event": "Log",
        "args": {
            "0": "reveive",
            "1": "0xAb8483F64d9C6d1EcF9b849Ae677dD3315835cb2",
            "2": "1",
            "3": "0x",
            "func": "reveive",
            "sender": "0xAb8483F64d9C6d1EcF9b849Ae677dD3315835cb2",
            "value": "1",
            "data": "0x"
        }
    }
]

• 当合约接收ETH的时候，receive()会被触发
• receive()最好不要执行太多的逻辑因为如果用send和transfer方法发送ETH的话，gas会限制在2300，receive()太复杂可能会触发Out of Gas报错
• 如果用call就可以自定义gas执行更复杂的逻辑（这三种发送ETH的方法我们之后会讲到）

13.2.2 fallback()函数

• fallback()函数会在调用合约不存在的函数时被触发, 也可用于接收ETH。
• fallback()声明时不需要function关键字，必须由external修饰，一般也会用payable修饰（用于接收ETH）
  示例：

contract ReceiveAndFallback {
    event Log(string func, address sender, uint256 value, bytes data);

    fallback() external payable {
        emit Log("fallback", msg.sender, msg.value, msg.data);
    }
}

向合约转入eth后的log：

[
    {
        "from": "0xAFEDB906F2735b26C635cAEE1039513dA8Ca2e90",
        "topic": "0xf7f75251dee7d7fc22deac3247729ebe7c86541f35930bf10c2a4207479a3b6c",
        "event": "Log",
        "args": {
            "0": "fallback",
            "1": "0xAb8483F64d9C6d1EcF9b849Ae677dD3315835cb2",
            "2": "1",
            "3": "0x11",
            "func": "fallback",
            "sender": "0xAb8483F64d9C6d1EcF9b849Ae677dD3315835cb2",
            "value": "1",
            "data": "0x11"
        }
    }
]

13.2.3 fallback()和reveive()函数的调用顺序

在向合约转入ETH时，会按照以下原则进行调用：

• 如果calldata（msg.data）不为空，则会调用fallback()；
• 如果calldata（msg.data）为空，则会看reveive()函数是否存在：
  • reveive()函数存在，优先调用reveive()函数；
  • reveive()函数不存在，调用fallback()函数。

触发fallback() 还是 receive()?
           接收ETH
              |
         msg.data是否为空？
            /  \
          是    否
          /      \
receive()存在?   fallback()
        / \
       是  否
      /     \
receive()   fallback()

13.3 发送ETH

智能合约中有三种方法发送ETH：

方法	消耗gas	返回结果
transfer	2300 gas	失败自动reverts
send	2300 gas	bool标记是否成功，需要自己处理回滚
call	all gas(自定义)	boo标记是否成功、data（向智能合约发送ETH时），需要自己处理回滚

示例：
定义一个接收ETH的合约：

contract ReceiveETH {
    event Log(uint256 amount, uint256 gas);

    receive() external payable {
        emit Log(msg.value, gasleft());
    }

    function getBalance() external view returns(uint) {
        return address(this).balance;
    }
}

定义一个发送ETH的合约：

contract SendETH {
    // 在部署时存入ETH，用于发送测试
    constructor() payable {}

    // transfer
    function sendViaTranser(address payable _to, uint256 _value) external {
        // 失败自动回滚
        _to.transfer(_value);
    }

    // send
    function sendViaSend(address payable _to, uint256 _value) external {
        bool success = _to.send(_value);
        // 处理失败
        require(success, "send failed");
    }

    // call
    function sendViaCall(address payable _to, uint256 _value) external {
        (bool success, bytes memory data) = _to.call{value:_value}("");
        // 处理失败
        require(success, string(data));
    }
}

• call没有gas限制（自定义），最为灵活；
• transfer有2300 gas限制，但是发送失败会自动revert交易，是次优选择；
• send有2300 gas限制，而且发送失败不会自动revert交易，几乎没有人用它。